[arch-commits] Commit in gnome-documents/repos (2 files)

[Jan Steffens]

    Date: Thursday, September 12, 2019 @ 21:57:20
  Author: heftig
Revision: 362361

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  gnome-documents/repos/gnome-unstable-x86_64/
  gnome-documents/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 362358, gnome-documents/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: gnome-documents/repos/gnome-unstable-x86_64/PKGBUILD (from rev 362358, gnome-documents/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2019-09-12 21:57:20 UTC (rev 362361)
@@ -0,0 +1,49 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+
+pkgname=gnome-documents
+pkgver=3.33.90+7+gcc19ed47
+pkgrel=1
+pkgdesc="A document manager application for GNOME"
+url="https://wiki.gnome.org/Apps/Documents"
+arch=(x86_64)
+license=(GPL)
+depends=(evince gjs gtk3 gnome-desktop gnome-online-accounts libgdata
+         tracker-miners libzapojit webkit2gtk gnome-online-miners librsvg
+         libgepub gnome-epub-thumbnailer)
+makedepends=(gobject-introspection git meson yelp-tools inkscape)
+optdepends=('libreoffice-fresh: Support for Libreoffice document types')
+groups=(gnome)
+_commit=cc19ed47cc81a59a379edefcc0e37c61803f51b4  # master
+source=("git+https://gitlab.gnome.org/GNOME/gnome-documents.git#commit=$_commit"
+        "git+https://gitlab.gnome.org/GNOME/libgd.git")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  git submodule init
+  git config --local submodule.subprojects/libgd.url "$srcdir/libgd"
+  git submodule update
+}
+  
+
+build() {
+  arch-meson $pkgname build -D getting_started=true
+  ninja -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}
+
+# vim:set ts=2 sw=2 et: