[arch-commits] Commit in gnome-calendar/repos (2 files)

[Jan Steffens]

    Date: Thursday, September 12, 2019 @ 22:34:29
  Author: heftig
Revision: 362379

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  gnome-calendar/repos/gnome-unstable-x86_64/
  gnome-calendar/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 362378, gnome-calendar/trunk/PKGBUILD)

----------+
 PKGBUILD |   41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

Copied: gnome-calendar/repos/gnome-unstable-x86_64/PKGBUILD (from rev 362378, gnome-calendar/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2019-09-12 22:34:29 UTC (rev 362379)
@@ -0,0 +1,41 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+
+pkgname=gnome-calendar
+pkgver=3.34.0
+pkgrel=1
+pkgdesc="Simple and beautiful calendar application designed to perfectly fit the GNOME desktop"
+url="https://wiki.gnome.org/Apps/Calendar"
+arch=(x86_64)
+license=(GPL)
+depends=(evolution-data-server gsettings-desktop-schemas gnome-control-center libdazzle)
+makedepends=(python appstream-glib git meson gtk-doc)
+optdepends=('evolution: ICS file import')
+groups=(gnome)
+_commit=5b49c4fc467b0f9b25597c188b66e95d7857c5ca  # tags/3.34.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-calendar.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+}
+
+build() {
+  arch-meson $pkgname build -D documentation=true
+  ninja -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}
+
+# vim:set ts=2 sw=2 et: