[arch-commits] Commit in cpp-hocon/repos (2 files)

[Evangelos Foutras]

    Date: Friday, September 13, 2019 @ 08:23:21
  Author: foutrelis
Revision: 510084

archrelease: copy trunk to community-staging-x86_64

Added:
  cpp-hocon/repos/community-staging-x86_64/
  cpp-hocon/repos/community-staging-x86_64/PKGBUILD
    (from rev 510083, cpp-hocon/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: cpp-hocon/repos/community-staging-x86_64/PKGBUILD (from rev 510083, cpp-hocon/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-09-13 08:23:21 UTC (rev 510084)
@@ -0,0 +1,46 @@
+# Maintainer: Christian Rebischke <chris.rebischke at archlinux.org>
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+
+pkgname=cpp-hocon
+pkgver=0.2.1
+pkgrel=4
+pkgdesc="C++ port of the Typesafe Config library"
+arch=('x86_64')
+url="https://github.com/puppetlabs/cpp-hocon"
+license=('APACHE')
+depends=('boost-libs' 'gcc-libs' 'glibc' 'leatherman' 'leatherman_util.so' 'leatherman_locale.so')
+makedepends=('boost' 'cmake' 'leatherman' 'rapidjson')
+provides=('libcpp-hocon.so')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/puppetlabs/cpp-hocon/archive/$pkgver.tar.gz")
+sha512sums=('fcc377da7923b77436a6f2787d5b8b1b573f239de4f059c4a5949cbb1a755fd12024b9155f5e44cf60141181942f3e9a2a8fad07ee0b1d516fe2cd4a88d4ac8b')
+
+build() {
+  cd "$pkgname-$pkgver"
+
+  mkdir -p build
+  cd build
+
+  cmake \
+    -DCMAKE_BUILD_TYPE=None \
+    -DENABLE_CXX_WERROR=OFF \
+    -DCMAKE_INSTALL_PREFIX:PATH=/usr \
+    -DBUILD_SHARED_LIBS=ON \
+    ..
+  make
+}
+
+check() {
+  cd "$pkgname-$pkgver"/build
+
+  make test
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+
+  make -C build install DESTDIR="$pkgdir"
+
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+# vim: ts=2 sw=2 et: