[arch-commits] Commit in gnome-terminal/repos (2 files)

Jan Steffens heftig at archlinux.org
Fri Sep 13 09:07:43 UTC 2019


    Date: Friday, September 13, 2019 @ 09:07:43
  Author: heftig
Revision: 362433

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  gnome-terminal/repos/gnome-unstable-x86_64/
  gnome-terminal/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 362432, gnome-terminal/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: gnome-terminal/repos/gnome-unstable-x86_64/PKGBUILD (from rev 362432, gnome-terminal/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2019-09-13 09:07:43 UTC (rev 362433)
@@ -0,0 +1,45 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+
+pkgname=gnome-terminal
+pkgver=3.34.0
+pkgrel=1
+pkgdesc="The GNOME Terminal Emulator"
+url="https://wiki.gnome.org/Apps/Terminal"
+arch=(x86_64)
+license=(GPL)
+depends=('vte3>=0.52.0' gsettings-desktop-schemas)
+makedepends=(intltool itstool docbook-xsl libnautilus-extension appstream-glib
+             gnome-shell vala yelp-tools git)
+groups=(gnome)
+_commit=deb38d2dff498aa4f45d762f781ef70460938163  # tags/3.34.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-terminal.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
+    --libexecdir=/usr/lib --disable-static --with-nautilus-extension
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+check() {
+  cd $pkgname
+  make check
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}


More information about the arch-commits mailing list