[arch-commits] Commit in anjuta/repos (2 files)

Jan Steffens heftig at archlinux.org
Fri Sep 13 12:34:42 UTC 2019


    Date: Friday, September 13, 2019 @ 12:34:42
  Author: heftig
Revision: 362523

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  anjuta/repos/gnome-unstable-x86_64/
  anjuta/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 362517, anjuta/trunk/PKGBUILD)

----------+
 PKGBUILD |   66 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)

Copied: anjuta/repos/gnome-unstable-x86_64/PKGBUILD (from rev 362517, anjuta/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2019-09-13 12:34:42 UTC (rev 362523)
@@ -0,0 +1,66 @@
+# Maintainer: Andreas Radke <andyrtr at archlinux.org>
+# Contributor: Harley Laue <losinggeneration at yahoo.com>
+
+pkgbase=anjuta
+pkgname=('libanjuta' 'anjuta')
+pkgver=3.34.0
+pkgrel=1
+pkgdesc="GNOME Integrated Development Environment (IDE)"
+arch=(x86_64)
+license=(GPL)
+makedepends=(gdl vte3 autogen devhelp glade libgda subversion neon vala dconf gtk-doc yelp-tools gnome-common intltool gobject-introspection itstool gjs git python)
+url="http://www.anjuta.org/"
+options=('!emptydirs')
+_commit=aaadfafe19450d8524400af9ae09d5187b2d627a  # master
+source=(https://download.gnome.org/sources/$pkgbase/${pkgver:0:4}/$pkgbase-$pkgver.tar.xz)
+sha256sums=('42a93130ed3ee02d064a7094e94e1ffae2032b3f35a87bf441e37fc3bb3a148f')
+
+prepare() {
+  cd $pkgbase-$pkgver
+
+  # vala 0.46
+  sed -i '/m4_foreach/s/0\.44/0.46/' configure.ac
+
+  AUTOPOINT="intltoolize" autoreconf -fvi
+}
+
+
+build() {
+  cd $pkgbase-$pkgver
+
+  ./configure --prefix=/usr --sysconfdir=/etc \
+      --localstatedir=/var \
+      --disable-compile-warnings \
+      --disable-schemas-compile \
+      --disable-silent-rules \
+      --disable-static \
+      --enable-introspection \
+      --enable-plugin-devhelp \
+      --enable-plugin-glade \
+      --enable-plugin-subversion \
+      --enable-glade-catalog --enable-gtk-doc
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+package_libanjuta(){
+  pkgdesc="Anjuta runtime library"
+  depends=(gdl)
+  conflicts=('anjuta<3.4.4')
+
+  cd $pkgbase-$pkgver/libanjuta
+
+  # j1: Race during linking
+  make -j1 DESTDIR="$pkgdir" install
+}
+
+package_anjuta(){
+  pkgdesc="GNOME Integrated Development Environment (IDE)"
+  depends=(libanjuta vte3 autogen devhelp glade libgda subversion neon vala dconf)
+
+  cd $pkgbase-$pkgver
+  make -j1 DESTDIR="$pkgdir" install
+
+  cd libanjuta
+  make -j1 DESTDIR="$pkgdir" uninstall
+}


More information about the arch-commits mailing list