[arch-commits] Commit in gnome-software/repos (2 files)

Jan Steffens heftig at archlinux.org
Fri Sep 13 13:40:50 UTC 2019


    Date: Friday, September 13, 2019 @ 13:40:48
  Author: heftig
Revision: 510332

archrelease: copy trunk to community-staging-x86_64

Added:
  gnome-software/repos/community-staging-x86_64/
  gnome-software/repos/community-staging-x86_64/PKGBUILD
    (from rev 510331, gnome-software/trunk/PKGBUILD)

----------+
 PKGBUILD |   68 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 68 insertions(+)

Copied: gnome-software/repos/community-staging-x86_64/PKGBUILD (from rev 510331, gnome-software/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-09-13 13:40:48 UTC (rev 510332)
@@ -0,0 +1,68 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+# Contributor: Yosef Or Boczko <yoseforb at gnome.org>
+
+pkgbase=gnome-software
+pkgname=(gnome-software gnome-software-packagekit-plugin)
+pkgver=3.34.0
+pkgrel=1
+pkgdesc="GNOME Software Tools"
+url="https://wiki.gnome.org/Apps/Software/"
+arch=(x86_64)
+license=(GPL2)
+makedepends=(appstream-glib gnome-desktop libpackagekit-glib flatpak fwupd ostree
+             docbook-xsl git gobject-introspection gspell gtk-doc meson valgrind
+             gnome-online-accounts libxmlb)
+_commit=8ea1b7d2d7b8cb91aa9053166803e05a9f464f42  # tags/3.34.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-software.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgbase
+  git describe --tags | sed 's/^GNOME_SOFTWARE_//;s/_/./g;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgbase
+}
+
+build() {
+  arch-meson $pkgbase build
+  ninja -C build
+}
+
+check() {
+  # build container troubles
+  meson test -C build --print-errorlogs || :
+}
+
+_pick() {
+  local p="$1" f d; shift
+  for f; do
+    d="$srcdir/$p/${f#$pkgdir/}"
+    mkdir -p "$(dirname "$d")"
+    mv "$f" "$d"
+    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
+  done
+}
+
+package_gnome-software() {
+  groups=('gnome')
+  depends=(libxmlb gnome-desktop gsettings-desktop-schemas gspell libpackagekit-glib
+           gnome-online-accounts appstream-glib)
+  optdepends=('flatpak: Flatpak support plugin'
+              'fwupd: fwupd support plugin'
+              'ostree: OSTree support plugin')
+
+  DESTDIR="$pkgdir" meson install -C build
+
+### Split gnome-software-packagekit-plugin
+  _pick packagekit-plugin "$pkgdir"/usr/lib/gs-plugins-*/libgs_plugin_packagekit*.so
+  _pick packagekit-plugin "$pkgdir"/usr/lib/gs-plugins-*/libgs_plugin_systemd-updates.so
+}
+
+package_gnome-software-packagekit-plugin() {
+  pkgdesc="PackageKit support plugin for GNOME Software"
+  depends=(archlinux-appstream-data gnome-software packagekit)
+  mv packagekit-plugin/* "$pkgdir"
+}



More information about the arch-commits mailing list