[arch-commits] Commit in gnome-panel/repos (3 files)

Jan Steffens heftig at archlinux.org
Fri Sep 13 21:26:56 UTC 2019


    Date: Friday, September 13, 2019 @ 21:26:55
  Author: heftig
Revision: 510401

archrelease: copy trunk to community-staging-x86_64

Added:
  gnome-panel/repos/community-staging-x86_64/
  gnome-panel/repos/community-staging-x86_64/PKGBUILD
    (from rev 510400, gnome-panel/trunk/PKGBUILD)
  gnome-panel/repos/community-staging-x86_64/gettext.diff
    (from rev 510400, gnome-panel/trunk/gettext.diff)

--------------+
 PKGBUILD     |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 gettext.diff |   12 ++++++++++++
 2 files changed, 58 insertions(+)

Copied: gnome-panel/repos/community-staging-x86_64/PKGBUILD (from rev 510400, gnome-panel/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-09-13 21:26:55 UTC (rev 510401)
@@ -0,0 +1,46 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgname=gnome-panel
+pkgver=3.34.0
+pkgrel=1
+pkgdesc="Panel of GNOME Flashback"
+arch=('x86_64')
+url="https://wiki.gnome.org/Projects/GnomePanel"
+license=('GPL')
+depends=('evolution-data-server' 'gnome-desktop' 'gnome-menus' 'libgdm' 'libwnck3' 'nautilus' 'polkit')
+makedepends=('intltool' 'itstool' 'python' 'git' 'gtk-doc' 'yelp-tools' 'autoconf-archive')
+optdepends=('alacarte: Main menu editor'
+            'gnome-applets: Extra applets for the panel')
+_commit=e78941f27e5edd560338da44e76cadfc0fc6ce9b  # tags/3.34.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-panel.git#commit=$_commit"
+        gettext.diff)
+sha256sums=('SKIP'
+            '0049e87e4d671ad4890239d3cb9a8652eabc616c2597a5930bcdd2ee31162127')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  patch -Np1 -i ../gettext.diff  # Unbreak build with gettext 0.20
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --libexecdir=/usr/lib/$pkgname \
+              --disable-schemas-compile --enable-compile-warnings=minimum --enable-gtk-doc
+
+  #https://bugzilla.gnome.org/show_bug.cgi?id=656231
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+  make
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}

Copied: gnome-panel/repos/community-staging-x86_64/gettext.diff (from rev 510400, gnome-panel/trunk/gettext.diff)
===================================================================
--- community-staging-x86_64/gettext.diff	                        (rev 0)
+++ community-staging-x86_64/gettext.diff	2019-09-13 21:26:55 UTC (rev 510401)
@@ -0,0 +1,12 @@
+diff --git i/configure.ac w/configure.ac
+index 873907512..fa39e0d31 100644
+--- i/configure.ac
++++ w/configure.ac
+@@ -79,6 +79,7 @@ dnl **************************************************************************
+ 
+ AM_GNU_GETTEXT([external])
+ AM_GNU_GETTEXT_VERSION([0.19.8])
++AM_GNU_GETTEXT_REQUIRE_VERSION([0.19.8])
+ 
+ GETTEXT_PACKAGE=gnome-panel
+ AC_SUBST([GETTEXT_PACKAGE])


More information about the arch-commits mailing list