[arch-commits] Commit in gnome-initial-setup/repos (2 files)

[Jan Steffens]

    Date: Friday, September 13, 2019 @ 21:35:07
  Author: heftig
Revision: 510406

archrelease: copy trunk to community-staging-x86_64

Added:
  gnome-initial-setup/repos/community-staging-x86_64/
  gnome-initial-setup/repos/community-staging-x86_64/PKGBUILD
    (from rev 510405, gnome-initial-setup/trunk/PKGBUILD)

----------+
 PKGBUILD |   37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

Copied: gnome-initial-setup/repos/community-staging-x86_64/PKGBUILD (from rev 510405, gnome-initial-setup/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-09-13 21:35:07 UTC (rev 510406)
@@ -0,0 +1,37 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+
+pkgname=gnome-initial-setup
+pkgver=3.34.0
+pkgrel=1
+pkgdesc="Simple, easy, and safe way to prepare a new system"
+arch=('x86_64')
+url="https://www.gnome.org/"
+license=('GPL')
+depends=('nm-connection-editor' 'accountsservice' 'cheese' 'gnome-desktop' 'libgweather'
+         'gnome-online-accounts' 'libgdm' 'libpwquality' 'libibus' 'libgnomekbd'
+         'libpackagekit-glib' 'geoclue')
+makedepends=('meson')
+optdepends=('gdm: GDM Initial Setup mode'
+            'gnome-getting-started-docs: GNOME Welcome Tour')
+source=(https://download.gnome.org/sources/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.xz)
+sha256sums=('4ca3855c526f520a6c93f9338779c20f0b404b65c21bb820a472ef2373479ea6')
+
+build() {
+  arch-meson $pkgname-$pkgver build -D region-page=true
+  ninja -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+  install -d -o root -g 102 -m 750 "$pkgdir/usr/share/polkit-1/rules.d"
+
+  # Setup system user and group
+  echo 'u gnome-initial-setup - "GNOME Initial Setup" /run/gnome-initial-setup' |
+    install -Dm644 /dev/stdin "$pkgdir/usr/lib/sysusers.d/$pkgname.conf"
+  echo 'd /run/gnome-initial-setup 0700 gnome-initial-setup gnome-initial-setup -' |
+    install -Dm644 /dev/stdin "$pkgdir/usr/lib/tmpfiles.d/$pkgname.conf"
+}