[arch-commits] Commit in fwupd/repos (2 files)
Filipe Laíns
ffy00 at archlinux.org
Mon Sep 16 11:34:26 UTC 2019
Date: Monday, September 16, 2019 @ 11:34:26
Author: ffy00
Revision: 510877
archrelease: copy trunk to community-testing-x86_64
Added:
fwupd/repos/community-testing-x86_64/
fwupd/repos/community-testing-x86_64/PKGBUILD
(from rev 510876, fwupd/trunk/PKGBUILD)
----------+
PKGBUILD | 63 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 63 insertions(+)
Copied: fwupd/repos/community-testing-x86_64/PKGBUILD (from rev 510876, fwupd/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD (rev 0)
+++ community-testing-x86_64/PKGBUILD 2019-09-16 11:34:26 UTC (rev 510877)
@@ -0,0 +1,63 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Contributor: Mirco Tischler <mt-ml at gmx dot de>
+
+pkgname=fwupd
+pkgver=1.3.1
+pkgrel=1
+pkgdesc="A simple daemon to allow session software to update firmware"
+arch=(x86_64)
+url="https://github.com/hughsie/fwupd"
+license=(LGPL)
+depends=(libxmlb efivar python libsmbios libgusb
+ libsoup json-glib gcab libarchive gpgme
+ libgudev polkit shared-mime-info modemmanager)
+makedepends=(meson valgrind gobject-introspection gtk-doc
+ python-cairo noto-fonts noto-fonts-cjk python-gobject vala
+ bash-completion python-pillow help2man gnu-efi-libs
+ tpm2-tss)
+optdepends=('tpm2-abrmd: TPM2 support'
+ 'tpm2-tools: TPM2 support')
+checkdepends=(umockdev)
+backup=('etc/fwupd/daemon.conf'
+ 'etc/fwupd/redfish.conf'
+ 'etc/fwupd/remotes.d/dell-esrt.conf'
+ 'etc/fwupd/remotes.d/fwupd-tests.conf'
+ 'etc/fwupd/remotes.d/lvfs-testing.conf'
+ 'etc/fwupd/remotes.d/lvfs.conf'
+ 'etc/fwupd/remotes.d/vendor-directory.conf'
+ 'etc/fwupd/remotes.d/vendor.conf'
+ 'etc/fwupd/uefi.conf')
+source=("https://people.freedesktop.org/~hughsient/releases/${pkgname}-${pkgver}.tar.xz"{,.asc})
+sha256sums=('6fcb6773a2e1fe12bd7aa86aebcfd2cb6a877f7400590abaad8347cc881f7aa0'
+ 'SKIP')
+validpgpkeys=(163EB50119225DB3DF8F49EA17ACBA8DFA970E17) # Richard Hughes <richard at hughsie.com>
+
+prepare() {
+ cd ${pkgname}-${pkgver}
+
+ # This tests are failing inside a chroot
+ sed -i "/test('uefi-self-test', e)/d" plugins/uefi/meson.build
+ sed -i "/test('dell-self-test', e)/d" plugins/dell/meson.build
+}
+
+build() {
+ cd ${pkgname}-${pkgver}
+ arch-meson -D b_lto=false ../build
+ ninja -v -C ../build
+}
+
+check() {
+ cd build
+ meson test
+}
+
+package() {
+ DESTDIR="${pkgdir}" ninja -C build install
+ # Fixup mode to match polkit
+ install -d -o root -g 102 -m 750 "${pkgdir}"/usr/share/polkit-1/rules.d
+ # Move D-BUS policy
+ mv "${pkgdir}"/{etc,usr/share}/dbus-1/system.d
+ rmdir "${pkgdir}"/etc/dbus-1
+ # Remove the tests
+ rm -r "${pkgdir}"/usr/share/installed-tests/
+}
More information about the arch-commits
mailing list