[arch-commits] Commit in (cereal cereal/repos cereal/trunk cereal/trunk/PKGBUILD)
Bruno Pagani
archange at archlinux.org
Wed Sep 18 11:27:59 UTC 2019
Date: Wednesday, September 18, 2019 @ 11:27:59
Author: archange
Revision: 511038
Initial addition of cereal into [community]
Now we just need some milk. ;)
Added:
cereal/
cereal/repos/
cereal/trunk/
cereal/trunk/PKGBUILD
----------+
PKGBUILD | 34 ++++++++++++++++++++++++++++++++++
1 file changed, 34 insertions(+)
Added: cereal/trunk/PKGBUILD
===================================================================
--- cereal/trunk/PKGBUILD (rev 0)
+++ cereal/trunk/PKGBUILD 2019-09-18 11:27:59 UTC (rev 511038)
@@ -0,0 +1,34 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+pkgname=cereal
+pkgver=1.2.2
+pkgrel=5
+pkgdesc="C++11 library for serialization"
+arch=(any)
+url="https://github.com/USCiLab/cereal"
+license=(BSD)
+makedepends=(boost cmake git)
+_tag=a167f00e4240a29fb2472907dc70a9b9867a2d02 # git rev-parse v${pkgver}
+source=(git+https://github.com/USCiLab/cereal.git#tag=${_tag})
+sha256sums=(SKIP)
+
+prepare() {
+ mkdir -p build
+}
+
+build() {
+ cd build
+
+ cmake ../${pkgname} \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DSKIP_PORTABILITY_TEST=ON \
+ -DTHREAD_SAFE=ON \
+ -DWITH_WERROR=OFF
+ make
+}
+
+package() {
+ make DESTDIR="${pkgdir}" -C build install
+ install -Dm644 ${pkgname}/LICENSE -t "${pkgdir}"/usr/share/licenses/${pkgname}
+}
More information about the arch-commits
mailing list