[arch-commits] Commit in freeglut/repos/extra-x86_64 (PKGBUILD PKGBUILD glut.diff)

Jan Steffens heftig at archlinux.org
Wed Sep 18 22:21:53 UTC 2019


    Date: Wednesday, September 18, 2019 @ 22:21:52
  Author: heftig
Revision: 363018

archrelease: copy trunk to extra-x86_64

Added:
  freeglut/repos/extra-x86_64/PKGBUILD
    (from rev 363015, freeglut/trunk/PKGBUILD)
  freeglut/repos/extra-x86_64/glut.diff
    (from rev 363015, freeglut/trunk/glut.diff)
Deleted:
  freeglut/repos/extra-x86_64/PKGBUILD

-----------+
 PKGBUILD  |   78 ++++++++++++++++++++++++++++++++----------------------------
 glut.diff |   21 ++++++++++++++++
 2 files changed, 63 insertions(+), 36 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2019-09-18 22:21:51 UTC (rev 363017)
+++ PKGBUILD	2019-09-18 22:21:52 UTC (rev 363018)
@@ -1,36 +0,0 @@
-# $Id$
-# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
-# Contributor: Eric Belanger <eric at archlinux.org>
-# Contributor: Tom Newsom <Jeepster at gmx.co.uk>
-
-pkgname=freeglut
-pkgver=3.0.0
-pkgrel=2
-pkgdesc="Provides functionality for small OpenGL programs"
-arch=(i686 x86_64)
-url="http://freeglut.sourceforge.net/"
-license=(MIT)
-depends=(libxi libxrandr libgl)
-makedepends=(mesa glu libxxf86vm cmake)
-replaces=(glut)
-provides=(glut)
-conflicts=(glut)
-source=(https://downloads.sourceforge.net/freeglut/${pkgname}-${pkgver}.tar.gz)
-md5sums=('90c3ca4dd9d51cf32276bc5344ec9754')
-sha1sums=('fca52242f9344627a30f11487ee42002e6b0dacd')
-
-prepare() {
-  mkdir build
-}
-
-build() {
-  cd build
-  cmake ../$pkgname-$pkgver -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_INSTALL_LIBDIR=lib -DCMAKE_BUILD_TYPE=Release
-  make
-}
-
-package() {
-  cd build
-  make DESTDIR="$pkgdir" install
-  install -Dm644 ../$pkgname-$pkgver/COPYING "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
-}

Copied: freeglut/repos/extra-x86_64/PKGBUILD (from rev 363015, freeglut/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2019-09-18 22:21:52 UTC (rev 363018)
@@ -0,0 +1,42 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Eric Belanger <eric at archlinux.org>
+# Contributor: Tom Newsom <Jeepster at gmx.co.uk>
+
+pkgname=freeglut
+pkgver=3.2.0
+pkgrel=1
+pkgdesc="Provides functionality for small OpenGL programs"
+arch=(x86_64)
+url="http://freeglut.sourceforge.net/"
+license=(MIT)
+depends=(libxi libxrandr libgl)
+makedepends=(mesa glu libxxf86vm cmake)
+replaces=(glut)
+provides=(glut)
+conflicts=(glut)
+source=(https://downloads.sourceforge.net/freeglut/${pkgname}-${pkgver}.tar.gz
+        glut.diff)
+sha512sums=('78da1eaa845607ddd97a6744f3a97ff26cdb562fdf990695c8ac97a60d9d692496e4bf3672acfc522add60823c2f3bc7435e19e8041fbbb5d95851c0b641a818'
+            '6778538722707460a7c71eceee430f3945fcfcff351d0a05623417a183af4e8f85a497e24208b73756b2713bb5c11d39dbd4e6de7f06b8865fd81a1faa23b9a4')
+
+prepare() {
+  cd $pkgname-$pkgver
+  patch -Np1 -i ../glut.diff
+}
+
+build() {
+  cmake -H$pkgname-$pkgver -Bbuild \
+    -DFREEGLUT_BUILD_STATIC_LIBS=OFF \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DCMAKE_BUILD_TYPE=None
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --build build --target install
+  ln -sr "$pkgdir"/usr/lib/pkgconfig/{glut,freeglut}.pc
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 $pkgname-$pkgver/COPYING
+}
+
+# vim: ts=2 sw=2 et:

Copied: freeglut/repos/extra-x86_64/glut.diff (from rev 363015, freeglut/trunk/glut.diff)
===================================================================
--- glut.diff	                        (rev 0)
+++ glut.diff	2019-09-18 22:21:52 UTC (rev 363018)
@@ -0,0 +1,21 @@
+diff -u -r freeglut-3.2.0/CMakeLists.txt freeglut-3.2.0-glut/CMakeLists.txt
+--- freeglut-3.2.0/CMakeLists.txt	2019-03-26 18:55:42.000000000 +0000
++++ freeglut-3.2.0-glut/CMakeLists.txt	2019-09-18 22:02:21.093590716 +0000
+@@ -73,7 +73,7 @@
+     include/GL/freeglut_std.h
+ )
+ IF(FREEGLUT_REPLACE_GLUT)
+-    LIST(APPEND FREEGLUT_SRCS
++    LIST(APPEND FREEGLUT_HEADERS
+         include/GL/glut.h
+     )
+ ENDIF()
+@@ -622,7 +622,7 @@
+     "${CMAKE_CURRENT_BINARY_DIR}/FreeGLUT/FreeGLUTConfig.cmake"
+     @ONLY
+ )
+-SET(ConfigPackageLocation lib/cmake/FreeGLUT)
++SET(ConfigPackageLocation ${CMAKE_INSTALL_LIBDIR}/cmake/FreeGLUT)
+ INSTALL(EXPORT FreeGLUTTargets
+     FILE FreeGLUTTargets.cmake
+     NAMESPACE FreeGLUT::


More information about the arch-commits mailing list