[arch-commits] Commit in python-urllib3/repos (3 files)

Felix Yan felixonmars at archlinux.org
Thu Sep 19 17:40:49 UTC 2019


    Date: Thursday, September 19, 2019 @ 17:40:48
  Author: felixonmars
Revision: 363084

archrelease: copy trunk to testing-any

Added:
  python-urllib3/repos/testing-any/
  python-urllib3/repos/testing-any/LICENSE
    (from rev 363083, python-urllib3/trunk/LICENSE)
  python-urllib3/repos/testing-any/PKGBUILD
    (from rev 363083, python-urllib3/trunk/PKGBUILD)

----------+
 LICENSE  |   32 ++++++++++++++++++++++++
 PKGBUILD |   80 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 112 insertions(+)

Copied: python-urllib3/repos/testing-any/LICENSE (from rev 363083, python-urllib3/trunk/LICENSE)
===================================================================
--- testing-any/LICENSE	                        (rev 0)
+++ testing-any/LICENSE	2019-09-19 17:40:48 UTC (rev 363084)
@@ -0,0 +1,32 @@
+Note from the ArchLinux Packager:
+The urllib3 source doesn't come with a license file.  Its homepage
+does provide a link to the text of the MIT license, so I copied
+the following text to a file when building the package.
+
+------CUT------
+Open Source Initiative OSI - The MIT License:Licensing
+
+
+[OSI Approved License]
+
+The MIT License
+
+Copyright (c) <year> <copyright holders>
+
+Permission is hereby granted, free of charge, to any person obtaining a copy
+of this software and associated documentation files (the "Software"), to deal
+in the Software without restriction, including without limitation the rights
+to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+copies of the Software, and to permit persons to whom the Software is
+furnished to do so, subject to the following conditions:
+
+The above copyright notice and this permission notice shall be included in
+all copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
+THE SOFTWARE.

Copied: python-urllib3/repos/testing-any/PKGBUILD (from rev 363083, python-urllib3/trunk/PKGBUILD)
===================================================================
--- testing-any/PKGBUILD	                        (rev 0)
+++ testing-any/PKGBUILD	2019-09-19 17:40:48 UTC (rev 363084)
@@ -0,0 +1,80 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Patrice Peterson <runiq at archlinux dot us>
+# Contributor: Chris Brannon <cmbrannon79 at gmail.com>
+# Contributor: BorgHunter <borghunter at gmail dot com>
+
+pkgbase=python-urllib3
+pkgname=(python-urllib3 python2-urllib3 python-urllib3-doc)
+pkgver=1.25.4
+pkgrel=1
+pkgdesc="HTTP library with thread-safe connection pooling and file post support"
+arch=("any")
+url="https://github.com/shazow/urllib3"
+license=("MIT")
+makedepends=('python-setuptools' 'python2-setuptools' 'python2-sphinx' 'python-ndg-httpsclient'
+             'python2-ndg-httpsclient' 'python-pyasn1' 'python2-pyasn1' 'python-pyopenssl'
+             'python2-pyopenssl' 'python-pysocks' 'python2-pysocks' 'python-mock' 'python2-mock'
+             'python-brotlipy' 'python2-brotlipy')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner' 'python-tornado' 'python2-tornado'
+              'python-nose' 'python2-nose' 'python-psutil' 'python2-psutil'
+              'python-gcp-devrel-py-tools' 'python2-gcp-devrel-py-tools')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/shazow/urllib3/archive/$pkgver.tar.gz")
+sha512sums=('b1b598d98644d293471a92a2e7d096d19ade0dd33b43c1af9a30a713cbfefd5cfc583a4cf240725b5b5d33a1c6ad351811310209befb7460a8b6a07dc226119d')
+
+prepare() {
+  sed -i 's/pytest/tool:pytest/' urllib3-$pkgver/setup.cfg
+  cp -a urllib3-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/urllib3-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/urllib3-$pkgver-py2
+  python2 setup.py build
+
+  # Build with Python 2 since autodoc produces errors on Python 3
+  cd "$srcdir"/urllib3-$pkgver/docs
+  make SPHINXBUILD=sphinx-build2 html
+}
+
+check() {
+  # Tests do not support Tornado 5
+
+  cd "$srcdir"/urllib3-$pkgver
+  python setup.py pytest || warning "Tests failed"
+
+  cd "$srcdir"/urllib3-$pkgver-py2
+  python2 setup.py pytest || warning "Tests failed"
+}
+
+package_python-urllib3() {
+  depends=('python')
+  optdepends=('python-pysocks: SOCKS support'
+              'python-brotlipy: Brotli support'
+              'python-pyopenssl: security support')
+
+  cd urllib3-$pkgver
+  python setup.py install --root="$pkgdir"
+  install -Dm644 LICENSE.txt "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.txt
+}
+
+package_python2-urllib3() {
+  depends=('python2')
+  optdepends=('python2-pysocks: SOCKS support'
+              'python2-brotlipy: Brotli support'
+              'python2-pyopenssl: security support')
+
+  cd urllib3-$pkgver-py2
+  python2 setup.py install --root="$pkgdir"
+  install -Dm644 LICENSE.txt "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.txt
+}
+
+package_python-urllib3-doc() {
+  pkgdesc="urllib3 Documentation"
+
+  cd urllib3-$pkgver/docs
+  install -d "$pkgdir"/usr/share/doc
+  cp -r _build/html "$pkgdir"/usr/share/doc/python-urllib3
+  install -Dm644 ../LICENSE.txt "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.txt
+}


More information about the arch-commits mailing list