[arch-commits] Commit in nextcloud-client/repos (2 files)

[Chih-Hsuan Yen]

    Date: Saturday, September 28, 2019 @ 05:56:26
  Author: yan12125
Revision: 511957

archrelease: copy trunk to community-testing-x86_64

Added:
  nextcloud-client/repos/community-testing-x86_64/
  nextcloud-client/repos/community-testing-x86_64/PKGBUILD
    (from rev 511956, nextcloud-client/trunk/PKGBUILD)

----------+
 PKGBUILD |   67 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)

Copied: nextcloud-client/repos/community-testing-x86_64/PKGBUILD (from rev 511956, nextcloud-client/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2019-09-28 05:56:26 UTC (rev 511957)
@@ -0,0 +1,67 @@
+# Maintainer: Chih-Hsuan Yen <yan12125 at archlinux.org>
+# Contributor: Tyler Dence <tyzoid at archlinux32.org>
+# Contributor: Konstantin Shalygin <k0ste at k0ste.ru>
+
+pkgname=nextcloud-client
+pkgver=2.6.0
+_commit=e0b32c19e4dd641f4edf74fc3fbdba3d86ca9784
+pkgrel=1
+pkgdesc='Nextcloud desktop client'
+arch=(x86_64)
+url='https://nextcloud.com/'
+license=(GPL)
+depends=(openssl sqlite qtkeychain qt5-svg qt5-webengine xdg-utils)
+makedepends=(doxygen extra-cmake-modules kio python-sphinx qt5-tools git cmocka)
+optdepends=(
+  'kio: integration with Dolphin'
+  'nemo-python: integration with Nemo'
+  'python-nautilus: integration with Nautilus'
+  'python2-caja: integration with Caja'
+)
+source=("$pkgname::git+https://github.com/nextcloud/desktop.git?signed#commit=$_commit")
+validpgpkeys=(
+  A26B951528EA1BA1678C7AE5D406C75CEE1A36D6  # one of keys controlled by github.com/camilasan
+)
+sha256sums=('SKIP')
+backup=('etc/Nextcloud/sync-exclude.lst')
+
+prepare() {
+  # tmpdir for check()
+  mkdir tmpdir $pkgname/build
+
+  # Use system GNUInstallDirs.cmake so that we can benefit from
+  # https://gitlab.kitware.com/cmake/cmake/merge_requests/3735
+  rm -v $pkgname/cmake/modules/GNUInstallDirs.cmake
+}
+
+build() {
+  cd $pkgname/build
+
+  # bundled breakpad in libcrashreporter-qt submodule is too old and does not build with glibc >= 2.26
+  # Upstream fix: https://github.com/google/breakpad/commit/bddcc58860f522a0d4cbaa7e9d04058caee0db9d
+  cmake \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DNO_SHIBBOLETH=1 \
+    -DWITH_CRASHREPORTER=OFF \
+    -DUNIT_TESTING=ON \
+    ..
+
+  make
+  # TODO: fix installation of PDF and HTML documents
+  # WIP at https://github.com/yan12125/desktop/tree/doc-install-path
+  make doc-man
+}
+
+check() {
+  cd $pkgname/build
+
+  # Tests fail if $TMPDIR is too small; specify an alternative for machines
+  # with a small /tmp partition.
+  TMPDIR="$srcdir/tmpdir" make test ARGS="-V"
+}
+
+package() {
+  cd $pkgname/build
+
+  make DESTDIR="$pkgdir" install
+}