[arch-commits] Commit in mutter/repos (3 files)

Jan Steffens heftig at archlinux.org
Sat Sep 28 13:35:14 UTC 2019


    Date: Saturday, September 28, 2019 @ 13:35:13
  Author: heftig
Revision: 363501

archrelease: copy trunk to testing-x86_64

Added:
  mutter/repos/testing-x86_64/
  mutter/repos/testing-x86_64/PKGBUILD
    (from rev 363500, mutter/trunk/PKGBUILD)
  mutter/repos/testing-x86_64/mutter.install
    (from rev 363500, mutter/trunk/mutter.install)

----------------+
 PKGBUILD       |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 mutter.install |    7 +++++++
 2 files changed, 59 insertions(+)

Copied: mutter/repos/testing-x86_64/PKGBUILD (from rev 363500, mutter/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2019-09-28 13:35:13 UTC (rev 363501)
@@ -0,0 +1,52 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Maintainer: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Michael Kanis <mkanis_at_gmx_dot_de>
+
+pkgname=mutter
+pkgver=3.34.0+41+g437f6b3d5
+pkgrel=1
+pkgdesc="A window manager for GNOME"
+url="https://gitlab.gnome.org/GNOME/mutter"
+arch=(x86_64)
+license=(GPL)
+depends=(dconf gobject-introspection-runtime gsettings-desktop-schemas libcanberra
+         startup-notification zenity libsm gnome-desktop upower libxkbcommon-x11
+         gnome-settings-daemon libgudev libinput pipewire xorg-server-xwayland)
+makedepends=(gobject-introspection git egl-wayland meson xorg-server sysprof)
+checkdepends=(xorg-server-xvfb)
+groups=(gnome)
+install=mutter.install
+_commit=437f6b3d59f2102f5974bfc430176725f2ed67c2  # master
+source=("git+https://gitlab.gnome.org/GNOME/mutter.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+}
+
+build() {
+  arch-meson $pkgname build \
+    -D egl_device=true \
+    -D wayland_eglstream=true \
+    -D installed_tests=false
+  ninja -C build
+}
+
+check() (
+  mkdir -p -m 700 "${XDG_RUNTIME_DIR:=$PWD/runtime-dir}"
+  glib-compile-schemas "${GSETTINGS_SCHEMA_DIR:=$PWD/build/data}"
+  export XDG_RUNTIME_DIR GSETTINGS_SCHEMA_DIR
+
+  # Unexpected passes in conform test
+  # Stacking test flaky
+  dbus-run-session xvfb-run -s '+iglx -noreset' meson test -C build --print-errorlogs || :
+)
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}

Copied: mutter/repos/testing-x86_64/mutter.install (from rev 363500, mutter/trunk/mutter.install)
===================================================================
--- testing-x86_64/mutter.install	                        (rev 0)
+++ testing-x86_64/mutter.install	2019-09-28 13:35:13 UTC (rev 363501)
@@ -0,0 +1,7 @@
+post_install() {
+  setcap cap_sys_nice+ep usr/bin/mutter
+}
+
+post_upgrade() {
+  post_install
+}


More information about the arch-commits mailing list