[arch-commits] Commit in haskell-storablevector/repos (2 files)

[Felix Yan]

    Date: Wednesday, April 1, 2020 @ 00:02:03
  Author: felixonmars
Revision: 608601

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-storablevector/repos/community-staging-x86_64/
  haskell-storablevector/repos/community-staging-x86_64/PKGBUILD
    (from rev 608600, haskell-storablevector/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: haskell-storablevector/repos/community-staging-x86_64/PKGBUILD (from rev 608600, haskell-storablevector/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-04-01 00:02:03 UTC (rev 608601)
@@ -0,0 +1,50 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=storablevector
+pkgname=haskell-storablevector
+pkgver=0.2.13
+pkgrel=40
+pkgdesc="Fast, packed, strict storable arrays with a list interface like ByteString"
+url="https://www.haskell.org/haskellwiki/Storable_Vector"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-non-negative' 'haskell-utility-ht' 'haskell-unsafe'
+         'haskell-quickcheck' 'haskell-syb')
+makedepends=('ghc' 'haskell-random')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('d2394fea10a8bb4bcd041f21bfc3580307a0c58f25e2b2b9adf7d2468bd1e632b4659c6da504c8dad062dfde472d1c2ccdd41731fb8b664e2bf7e0f3de55343c')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i '/semigroups/d' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -fsplitbase -fseparatesyb
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}