[arch-commits] Commit in haskell-monad-control/repos (2 files)

[Felix Yan]

    Date: Wednesday, April 1, 2020 @ 11:46:24
  Author: felixonmars
Revision: 608793

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-monad-control/repos/community-staging-x86_64/
  haskell-monad-control/repos/community-staging-x86_64/PKGBUILD
    (from rev 608792, haskell-monad-control/trunk/PKGBUILD)

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Copied: haskell-monad-control/repos/community-staging-x86_64/PKGBUILD (from rev 608792, haskell-monad-control/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-04-01 11:46:24 UTC (rev 608793)
@@ -0,0 +1,38 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=monad-control
+pkgname=haskell-monad-control
+pkgver=1.0.2.3
+pkgrel=66
+pkgdesc="Lift control operations, like exception catching, through monad transformers"
+url="https://github.com/basvandijk/monad-control"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' "haskell-transformers-base" "haskell-transformers-compat")
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('59837326ec9f25220cb6c7329c91a5806b0ec7412d6af24c0f0d52c4fd93b084e92edd4f5f61a4f9c4248034fa540c23b65d2aacdfca737ece98bb132b8f08d4')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}