[arch-commits] Commit in haskell-enclosed-exceptions/repos (2 files)

[Felix Yan]

    Date: Wednesday, April 1, 2020 @ 11:47:31
  Author: felixonmars
Revision: 608797

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-enclosed-exceptions/repos/community-staging-x86_64/
  haskell-enclosed-exceptions/repos/community-staging-x86_64/PKGBUILD
    (from rev 608796, haskell-enclosed-exceptions/trunk/PKGBUILD)

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Copied: haskell-enclosed-exceptions/repos/community-staging-x86_64/PKGBUILD (from rev 608796, haskell-enclosed-exceptions/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-04-01 11:47:31 UTC (rev 608797)
@@ -0,0 +1,38 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=enclosed-exceptions
+pkgname=haskell-enclosed-exceptions
+pkgver=1.0.3
+pkgrel=53
+pkgdesc="Catching all exceptions from within an enclosed computation"
+url="https://github.com/jcristovao/enclosed-exceptions"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' "haskell-lifted-base" "haskell-monad-control" "haskell-transformers-base")
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('68edb501f42f01d8b4bbce374e49295e045650a8b19fdbf527a54458728e61f53c6c6bcfd1613a7169b013a34bd51cbd2ab2c457cf616fbc8c052b98533bde6c')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}