[arch-commits] Commit in haskell-unordered-containers/repos (2 files)

[Felix Yan]

    Date: Wednesday, April 1, 2020 @ 12:04:33
  Author: felixonmars
Revision: 608843

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-unordered-containers/repos/community-staging-x86_64/
  haskell-unordered-containers/repos/community-staging-x86_64/PKGBUILD
    (from rev 608842, haskell-unordered-containers/trunk/PKGBUILD)

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Copied: haskell-unordered-containers/repos/community-staging-x86_64/PKGBUILD (from rev 608842, haskell-unordered-containers/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-04-01 12:04:33 UTC (rev 608843)
@@ -0,0 +1,54 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Daniel Nagy <danielnagy at gmx de>
+# Contributor: Daniel Micay <danielmicay at gmail.com>
+# Contributor: Martin Harvan <martinhrvn at gmail.com>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=unordered-containers
+pkgname=haskell-unordered-containers
+pkgver=0.2.10.0
+pkgrel=37
+pkgdesc="Efficient hashing-based container types"
+url="https://github.com/tibbe/unordered-containers"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-hashable')
+makedepends=('ghc' 'haskell-chasingbottoms' 'haskell-hunit' 'haskell-quickcheck'
+             'haskell-test-framework' 'haskell-test-framework-hunit'
+             'haskell-test-framework-quickcheck2')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('450e5e839e0092b2476a0abfc3eb2f45fba634a9e782cddf25b3db3730d16dd2e65673f46678ab4ad23be71525ae5f72888b89b03402cb70e20fc33feb765766')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i 's/< *1.3/<2/' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-debug
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}