[arch-commits] Commit in subsurface/repos (2 files)

[Gaëtan Bisson]

    Date: Thursday, April 2, 2020 @ 02:25:54
  Author: bisson
Revision: 609348

archrelease: copy trunk to community-staging-x86_64

Added:
  subsurface/repos/community-staging-x86_64/
  subsurface/repos/community-staging-x86_64/PKGBUILD
    (from rev 609347, subsurface/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: subsurface/repos/community-staging-x86_64/PKGBUILD (from rev 609347, subsurface/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-04-02 02:25:54 UTC (rev 609348)
@@ -0,0 +1,45 @@
+# Contributor: Francois Boulogne <fboulogne at april dot org>
+# Maintainer: Gaetan Bisson <bisson at archlinux.org>
+
+pkgname=subsurface
+_pkgname=Subsurface
+pkgver=4.9.3
+pkgrel=3
+pkgdesc='Divelog program'
+url='https://subsurface-divelog.org/'
+license=('GPL2')
+arch=('x86_64')
+makedepends=('cmake' 'asciidoc' 'qt5-tools')
+depends=('libzip' 'libxml2' 'libxslt' 'sqlite' 'libusb' 'libgit2'
+         'subsurface-libdc' 'qt5-svg' 'qt5-location'
+         'qt5-connectivity' 'qt5-webkit' 'grantlee' 'googlemaps')
+source=("https://subsurface-divelog.org/downloads/${_pkgname}-${pkgver}.tgz")
+sha256sums=('8e35ae13d0ca703da412ebef2e21ddc59cc63a0d7a1da6143654375c20b105b8')
+
+# qt5-webkit still used for: printing, manual, facebook
+
+prepare() {
+	cd "${srcdir}/${_pkgname}-${pkgver}"
+	sed \
+		-e 's/GIT_MERGE_TREE_/GIT_MERGE_/g' \
+		-e 's/tree_flags/flags/g' \
+		-i core/git-access.c
+}
+
+build() {
+	cd "${srcdir}/${_pkgname}-${pkgver}"
+	install -d build
+	cd build
+	cmake \
+		-DCMAKE_BUILD_TYPE=Release \
+		-DCMAKE_INSTALL_PREFIX=/usr \
+		-DLIBDIVECOMPUTER_INCLUDE_DIR=/usr/include/libdivecomputer \
+		..
+	make
+}
+
+package() {
+	cd "${srcdir}/${_pkgname}-${pkgver}"
+	cd build
+	make DESTDIR="${pkgdir}" install
+}