[arch-commits] Commit in tp_smapi-lts/repos (2 files)

[Andreas Radke]

    Date: Thursday, April 2, 2020 @ 15:25:21
  Author: andyrtr
Revision: 609612

archrelease: copy trunk to community-testing-x86_64

Added:
  tp_smapi-lts/repos/community-testing-x86_64/
  tp_smapi-lts/repos/community-testing-x86_64/PKGBUILD
    (from rev 609611, tp_smapi-lts/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: tp_smapi-lts/repos/community-testing-x86_64/PKGBUILD (from rev 609611, tp_smapi-lts/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2020-04-02 15:25:21 UTC (rev 609612)
@@ -0,0 +1,50 @@
+# Maintainer: Lukas Fleischer <lfleischer at archlinux.org>
+# Contributor: xduugu
+# Contributor: nh2
+# Contributor: Steven Davidovitz <steviedizzle ð gmail đ com>
+# Contributor: Nick B <Shirakawasuna ð gmail đ com>
+# Contributor: Christof Musik <christof ð senfdax đ de>
+# Contributor: Stefan Rupp <archlinux ð stefanrupp đ de>
+# Contributor: Ignas Anikevicius <anikevicius ð gmail đ com>
+
+pkgname=tp_smapi-lts
+pkgver=0.43
+pkgrel=52
+pkgdesc="Modules for ThinkPad's SMAPI functionality"
+arch=('x86_64')
+url='https://github.com/evgeni/tp_smapi'
+license=('GPL')
+makedepends=('linux-lts-headers' 'git')
+_commit=a63729ab30d85430048f65c37f29188ab484cd52  # tags/tp-smapi/0.43
+source=("git+https://github.com/evgeni/tp_smapi#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd tp_smapi
+  git describe --tags | sed 's/^tp-smapi\///;s/-/+/g'
+}
+
+build() {
+  cd tp_smapi
+
+  # https://bugs.archlinux.org/task/54975 (kernel has no _GLOBAL_OFFSET_TABLE_):
+  # Clear EXTRA_CFLAGS since it defaults to injecting CFLAGS and -fno-plt breaks the modules
+
+  make HDAPS=1 KVER="$(</usr/src/linux-lts/version)" EXTRA_CFLAGS=
+}
+
+package() {
+  depends=('linux-lts')
+
+  local extradir=/usr/lib/modules/$(</usr/src/linux-lts/version)/extramodules
+  cd tp_smapi
+
+  # install kernel modules
+  find . -name "*.ko" -exec install -Dt "$pkgdir$extradir" {} +
+
+  # compress kernel modules
+  find "$pkgdir" -name "*.ko" -exec xz {} +
+
+  # load module on startup
+  echo tp_smapi | install -Dm644 /dev/stdin "$pkgdir/usr/lib/modules-load.d/$pkgname.conf"
+}