[arch-commits] Commit in root/repos (9 files)

Konstantin Gizdov kgizdov at archlinux.org
Thu Apr 2 17:10:26 UTC 2020


    Date: Thursday, April 2, 2020 @ 17:10:25
  Author: kgizdov
Revision: 610155

archrelease: copy trunk to community-testing-x86_64

Added:
  root/repos/community-testing-x86_64/
  root/repos/community-testing-x86_64/PKGBUILD
    (from rev 610154, root/trunk/PKGBUILD)
  root/repos/community-testing-x86_64/ROOFIT_LICENSE
    (from rev 610154, root/trunk/ROOFIT_LICENSE)
  root/repos/community-testing-x86_64/add_missing_include_ROOT-10315.patch
    (from rev 610154, root/trunk/add_missing_include_ROOT-10315.patch)
  root/repos/community-testing-x86_64/fix_relative_paths.patch
    (from rev 610154, root/trunk/fix_relative_paths.patch)
  root/repos/community-testing-x86_64/root.pc.tpl
    (from rev 610154, root/trunk/root.pc.tpl)
  root/repos/community-testing-x86_64/root.xml
    (from rev 610154, root/trunk/root.xml)
  root/repos/community-testing-x86_64/settings-cuda.cmake
    (from rev 610154, root/trunk/settings-cuda.cmake)
  root/repos/community-testing-x86_64/settings.cmake
    (from rev 610154, root/trunk/settings.cmake)

--------------------------------------+
 PKGBUILD                             |  231 +++++++++++++++++++++++++++++++++
 ROOFIT_LICENSE                       |   22 +++
 add_missing_include_ROOT-10315.patch |   22 +++
 fix_relative_paths.patch             |   39 +++++
 root.pc.tpl                          |   12 +
 root.xml                             |   14 ++
 settings-cuda.cmake                  |  100 ++++++++++++++
 settings.cmake                       |   99 ++++++++++++++
 8 files changed, 539 insertions(+)

Copied: root/repos/community-testing-x86_64/PKGBUILD (from rev 610154, root/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2020-04-02 17:10:25 UTC (rev 610155)
@@ -0,0 +1,231 @@
+# Maintainer: Konstantin Gizdov < arch at kge dot pw >
+# Contributor: Frank Siegert < frank.siegert at googlemail dot com >
+# Contributor: Scott Lawrence < bytbox at gmail dot com >
+# Contributor: Thomas Dziedzic < gostrc at gmail dot com >
+# Contributor: Sebastian Voecking < voeck at web dot de >
+
+pkgbase=root
+pkgname=('root' 'root-cuda')
+pkgver=6.20.02
+pkgrel=2
+pkgdesc='C++ data analysis framework and interpreter from CERN'
+arch=('x86_64')
+url='https://root.cern'
+license=('LGPL2.1' 'GPL' 'custom:University of California and Stanford University License')
+makedepends=('ccache'
+             'cern-vdt'
+             'cfitsio'
+             'cmake'
+             'cuda'
+             'cudnn'
+             'gcc-fortran'
+             'gcc8-fortran'
+             'git'
+             'go'
+             'libxml2'
+             'libmariadbclient'
+             'ocaml'
+             'ocaml-ctypes'
+             'openssl'
+             'postgresql-libs'
+             'pythia8>=8.2.40-1'
+             'sqlite'
+             'unuran'
+             'vc'
+             'xrootd>=4.6.0-2'
+             'z3')
+depends=('blas'
+         'desktop-file-utils'
+         'fcgi'
+         'fftw'
+         'ftgl'
+         'giflib'
+         'gl2ps'
+         'glew'
+         'graphviz'
+         'gsl'
+         'hicolor-icon-theme'
+         'intel-tbb'
+         'libafterimage'
+         'librsvg'
+         'libxpm'
+         'python'
+         'python-numpy'
+         'tex-gyre-fonts'
+         'unixodbc'
+         'xxhash>=0.6.5-1'
+         'zstd')
+optdepends=('cern-vdt: Add a set of fast and vectorisable mathematical functions'
+            'cfitsio: Read images and data from FITS files'
+            'libmariadbclient: MySQL support'
+            'libxml2: XML parser interface'
+            'openssl: OpenSSL support'
+            'postgresql-libs: PostgreSQL support'
+            'pythia8>=8.2.40-1: Pythia8 EG support'
+            'sqlite: SQLite support'
+            'tcsh: Legacy CSH support'
+            'unuran: Support non-uniform random numbers'
+            'vc: Add types for portable and intuitive SIMD programming'
+            'xrootd: Support remote file server and client'
+            'z3: Suuport the Z3 theorem prover')
+source=("https://root.cern.ch/download/root_v${pkgver}.source.tar.gz"
+        'ROOFIT_LICENSE'
+        'root.xml'
+        'root.pc.tpl'
+        'settings.cmake'
+        'settings-cuda.cmake'
+        'add_missing_include_ROOT-10315.patch'
+        'fix_relative_paths.patch')
+sha256sums=('0997586bf097c0afbc6f08edbffcebf5eb6a4237262216114ba3f5c8087dcba6'
+            '43fb857c82c23016dc9ae82a591503c47d12ecbc576cb8285aa632b3e83b9839'
+            '50c08191a5b281a39aa05ace4feb8d5405707b4c54a5dcba061f954649c38cb0'
+            '558b1c882ce166ad27349460f4da2a81a9a429ad0b5e802601b6ee2714610b0e'
+            '54cae85b8ff132cd0de6654048797281a7725efaa8158a3b97ea21ce8f258ebd'
+            'b1cad3e74be54ea7ef65a522d726e608b7f5b451c036c4cbb7511f454f015f4c'
+            '1cb2654f22b5f1de7f8621434c76266968db77a1f300de857e47d0f4ad5da217'
+            'd5b135fb4d6329277e33d612f8b81b1ca60681cca96196e33ab776f3018a2fa8')
+
+get_pyver () {
+    python -c 'import sys; print(str(sys.version_info[0]) + "." + str(sys.version_info[1]))'
+}
+
+prepare() {
+    local src
+    for src in "${source[@]}"; do
+        src="${src%%::*}"
+        src="${src##*/}"
+        [[ $src = *.patch ]] || continue
+        echo "  -> Applying patch $src..."
+        patch -Np1 -i "../$src" -d "${srcdir}/${pkgbase}-${pkgver}"
+    done
+
+    # specify some custom flags
+    # needed by vc to link properly
+    CUSTOM_CMAKE_FLAGS="-DTARGET_ARCHITECTURE:STRING=generic"
+    # make sure it finds python
+    CUSTOM_CMAKE_FLAGS+=" -DPYTHON_EXECUTABLE:PATH=/usr/bin/python"
+    # need to set install prefix like so
+    CUSTOM_CMAKE_FLAGS+=" -DINSTALL_PREFIX=/usr"
+    export CUSTOM_CMAKE_FLAGS
+
+    # update system flags
+    # don't let ROOT play around with lib paths
+    # the following is no longer necessary
+    # sed -i -e 's at SetLibraryPath();@@g' \
+    #     "${srcdir}/${pkgbase}-${pkgver}/rootx/src/rootx.cxx"
+    # now only depends on IS_RPATH_BUILD being set
+    # so pass it to GCC
+    export CPPFLAGS="${CPPFLAGS} -DIS_RPATH_BUILD=1"
+    # make sure pthread gets detected
+    CUSTOM_COMPILER_FLAGS="${CPPFLAGS} -pthread"
+    export CFLAGS="${CFLAGS} ${CUSTOM_COMPILER_FLAGS}"
+    export CXXFLAGS="${CXXFLAGS} ${CUSTOM_COMPILER_FLAGS}"
+    # do not link undefined
+    CUSTOM_COMPILER_FLAGS+=" -Wl,--no-undefined"
+    export LDFLAGS="${LDFLAGS} ${CUSTOM_COMPILER_FLAGS}"
+
+    # go flags for built-in clang
+    export CGO_LDFLAGS="${LDFLAGS}"
+    export GOFLAGS="-buildmode=pie -trimpath -modcacherw"
+
+    cp -r "${pkgbase}-${pkgver}" "${pkgbase}-${pkgver}-cuda"
+}
+
+build() {
+    ## ROOT
+    mkdir -p "${srcdir}/build"
+    cd "${srcdir}/build"
+
+    cmake -C "${srcdir}/settings.cmake" \
+        ${CUSTOM_CMAKE_FLAGS} \
+        "${srcdir}/${pkgbase}-${pkgver}"
+    make
+
+    ## ROOT with CUDA
+    mkdir -p "${srcdir}/build-cuda"
+    cd "${srcdir}/build-cuda"
+
+    CC=/usr/bin/gcc-8 \
+    CXX=/usr/bin/g++-8 \
+    cmake -C "${srcdir}/settings-cuda.cmake" \
+        ${CUSTOM_CMAKE_FLAGS} \
+        "${srcdir}/${pkgbase}-${pkgver}-cuda"
+    make
+}
+
+_package() {
+    local bld_dir="${srcdir}/${1}"
+    cd "${bld_dir}"
+
+    make DESTDIR="${pkgdir}" install
+
+    # fix python env call
+    sed -e 's/@python@/python/' -i "${pkgdir}/usr/lib/root/cmdLineUtils.py"
+
+    # try to deal with weird PyROOT, PyMVA and JupyROOT stuff
+    rm -rf "${pkgdir}/usr/lib/root/__pycache__"
+    local _pyver=$(get_pyver)
+    local _pydir="${pkgdir}/usr/lib/python${_pyver}/site-packages"
+    install -d "${_pydir}"
+    find "${pkgdir}/usr/lib/root" -maxdepth 1 -mindepth 1 \( -iname "*py*" -or -name "*Js*" \) ! -name "*EGPythia8*" -print0 | while read -rd $'\0' _lib; do
+        _base=$(basename "${_lib}")
+        ln -sf "/usr/lib/root/${_base}" "${pkgdir}/usr/lib/python${_pyver}/site-packages/${_base}"
+    done
+
+    # recompile pycache to strip $pkgdir from embedded paths
+    python -m compileall -d "/usr/lib/python${_pyver}" \
+        "${pkgdir}/usr/lib/python${_pyver}"
+    python -O -m compileall -d "/usr/lib/python${_pyver}" \
+        "${pkgdir}/usr/lib/python${_pyver}"
+
+    # icon, shortcut and mime
+    install -Dm644 "${srcdir}/${pkgbase}-${pkgver}/icons/Root6Icon.png" \
+        "${pkgdir}/usr/share/icons/hicolor/48x48/apps/root.png"
+    install -Dm644 "${srcdir}/${pkgbase}-${pkgver}/etc/root.desktop" \
+        "${pkgdir}/usr/share/applications/root.desktop"
+    echo 'Icon=root.png' >> "${pkgdir}/usr/share/applications/root.desktop"
+    install -Dm644 "${srcdir}/root.xml" \
+        "${pkgdir}/usr/share/mime/packages/root.xml"
+
+    # use a file that pacman can track instead of adding directly to ld.so.conf
+    install -d "${pkgdir}/etc/ld.so.conf.d"
+    echo '/usr/lib/root' > "${pkgdir}/etc/ld.so.conf.d/root.conf"
+
+    # create pkg-config file
+    local _prefix _exec_prefix _bindir _libdir _incdir _pkg_ver _libs _cflags _requires
+    _prefix="$("${pkgdir}"/usr/bin/root-config --prefix)"
+    _exec_prefix="$("${pkgdir}"/usr/bin/root-config --exec-prefix)"
+    _bindir="$("${pkgdir}"/usr/bin/root-config --bindir)"
+    _libdir="$("${pkgdir}"/usr/bin/root-config --libdir)"
+    _incdir="$("${pkgdir}"/usr/bin/root-config --incdir)"
+    _pkg_ver="$(sed -n 's,.*ROOT_RELEASE *\"\(.*\)\".*,\1,p' < "${pkgdir}"/usr/include/RVersion.h)"
+    _libs="$("${pkgdir}"/usr/bin/root-config --libs)"
+    _cflags="$("${pkgdir}"/usr/bin/root-config --cflags)"
+    printf -v _requires '%s,' "${depends[@]}"
+    cp "${srcdir}/root.pc.tpl" "${bld_dir}"/
+    sed -e "s at _PREFIX@${_prefix}@" -e "s at _EXECPREFIX@${_exec_prefix}@" \
+        -e "s at _LIBDIR@${_libdir}@" -e "s at _INCDIR@${_incdir}@" \
+        -e "s at _PKGVERSION@${_pkg_ver}@" -e "s at _LIBRARIES@${_libs}@" \
+        -e "s at _CFLAGS@${_cflags}@" -e "s at _UPSTREAM_URL@${url}@" \
+        -e "s at _REQUIRES@${_requires}@" \
+        -i "${bld_dir}/root.pc.tpl"
+    install -Dm644 "${bld_dir}/root.pc.tpl" "${pkgdir}/usr/lib/pkgconfig/root.pc"
+
+    # install all licenses
+    install -d "${pkgdir}/usr/share/licenses/roofit"
+    install "${srcdir}/ROOFIT_LICENSE" "${pkgdir}/usr/share/licenses/roofit/LICENSE"
+}
+
+package_root() {
+    optdepends+=('gcc-fortran: Enable the Fortran components of ROOT')
+    _package build
+}
+
+package_root-cuda() {
+    pkgdesc='C++ data analysis framework and interpreter from CERN with GPU (CUDA) features enabled'
+    provides=('root')
+    conflicts=('root')
+    depends+=('cuda' 'cudnn')
+    optdepends+=('gcc8-fortran: Enable the Fortran components of ROOT')
+    _package build-cuda
+}

Copied: root/repos/community-testing-x86_64/ROOFIT_LICENSE (from rev 610154, root/trunk/ROOFIT_LICENSE)
===================================================================
--- community-testing-x86_64/ROOFIT_LICENSE	                        (rev 0)
+++ community-testing-x86_64/ROOFIT_LICENSE	2020-04-02 17:10:25 UTC (rev 610155)
@@ -0,0 +1,22 @@
+RooFit --- Copyright (c) 2000-2005, Regents of the University of California and Stanford University
+All rights reserved.
+
+Redistribution and use in source and binary forms, with or without modification,
+are permitted provided that the following conditions are met:
+
+  - Redistributions of source code must retain the above copyright notice,
+    this list of conditions and the following disclaimer.
+
+  - Redistributions in binary form must reproduce the above copyright notice,
+    this list of conditions and the following disclaimer in the documentation
+    and/or other materials provided with the distribution.
+
+THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS
+OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
+MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
+COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
+EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
+SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
+CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
+(INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN
+IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.

Copied: root/repos/community-testing-x86_64/add_missing_include_ROOT-10315.patch (from rev 610154, root/trunk/add_missing_include_ROOT-10315.patch)
===================================================================
--- community-testing-x86_64/add_missing_include_ROOT-10315.patch	                        (rev 0)
+++ community-testing-x86_64/add_missing_include_ROOT-10315.patch	2020-04-02 17:10:25 UTC (rev 610155)
@@ -0,0 +1,22 @@
+From e31986c6523253f3160753b202e22a1c321e2b1a Mon Sep 17 00:00:00 2001
+From: Sergey Linev <S.Linev at gsi.de>
+Date: Thu, 12 Sep 2019 14:06:13 +0200
+Subject: [PATCH] [rbrowser] add missing include ROOT-10315
+
+---
+ gui/browserv7/inc/ROOT/RBrowserItem.hxx | 3 +++
+ 1 file changed, 3 insertions(+)
+
+diff --git a/gui/browserv7/inc/ROOT/RBrowserItem.hxx b/gui/browserv7/inc/ROOT/RBrowserItem.hxx
+index b21bc87b4bf..e9ae97e90c0 100644
+--- a/gui/browserv7/inc/ROOT/RBrowserItem.hxx
++++ b/gui/browserv7/inc/ROOT/RBrowserItem.hxx
+@@ -17,6 +17,9 @@
+ #ifndef ROOT7_RBrowserItem
+ #define ROOT7_RBrowserItem
+ 
++#include <string>
++#include <vector>
++
+ namespace ROOT {
+ namespace Experimental {

Copied: root/repos/community-testing-x86_64/fix_relative_paths.patch (from rev 610154, root/trunk/fix_relative_paths.patch)
===================================================================
--- community-testing-x86_64/fix_relative_paths.patch	                        (rev 0)
+++ community-testing-x86_64/fix_relative_paths.patch	2020-04-02 17:10:25 UTC (rev 610155)
@@ -0,0 +1,39 @@
+diff --git a/cmake/modules/RootConfiguration.cmake b/cmake/modules/RootConfiguration.cmake
+index 41a9cffc78..1c70ce8e39 100644
+--- a/cmake/modules/RootConfiguration.cmake
++++ b/cmake/modules/RootConfiguration.cmake
+@@ -678,22 +678,30 @@ file(RELATIVE_PATH ROOT_CMAKE_TO_INCLUDE_DIR "${CMAKE_INSTALL_FULL_CMAKEDIR}" "$
+ file(RELATIVE_PATH ROOT_CMAKE_TO_LIB_DIR "${CMAKE_INSTALL_FULL_CMAKEDIR}" "${CMAKE_INSTALL_FULL_LIBDIR}")
+ file(RELATIVE_PATH ROOT_CMAKE_TO_BIN_DIR "${CMAKE_INSTALL_FULL_CMAKEDIR}" "${CMAKE_INSTALL_FULL_BINDIR}")
+ 
++# '_' prefixed variables are used to construct the paths,
++# while the normal variants evaluate to full paths at runtime
+ set(ROOT_INCLUDE_DIR_SETUP "
+ # ROOT configured for the install with relative paths, so use these
+-get_filename_component(ROOT_INCLUDE_DIRS \"\${_thisdir}/${ROOT_CMAKE_TO_INCLUDE_DIR}\" ABSOLUTE)
++get_filename_component(_ROOT_INCLUDE_DIRS \"\${_thisdir}/${ROOT_CMAKE_TO_INCLUDE_DIR}\" REALPATH)
++# resolve relative paths to absolute system paths
++get_filename_component(ROOT_INCLUDE_DIRS \"\${_ROOT_INCLUDE_DIRS}\" REALPATH)
+ ")
+ set(ROOT_LIBRARY_DIR_SETUP "
+ # ROOT configured for the install with relative paths, so use these
+-get_filename_component(ROOT_LIBRARY_DIR \"\${_thisdir}/${ROOT_CMAKE_TO_LIB_DIR}\" ABSOLUTE)
++get_filename_component(_ROOT_LIBRARY_DIR \"\${_thisdir}/${ROOT_CMAKE_TO_LIB_DIR}\" REALPATH)
++# resolve relative paths to absolute system paths
++get_filename_component(ROOT_LIBRARY_DIR \"\${_ROOT_LIBRARY_DIR}\" REALPATH)
+ ")
+ set(ROOT_BINDIR_SETUP "
+ # ROOT configured for the install with relative paths, so use these
+-get_filename_component(ROOT_BINDIR \"\${_thisdir}/${ROOT_CMAKE_TO_BIN_DIR}\" ABSOLUTE)
++get_filename_component(_ROOT_BINDIR \"\${_thisdir}/${ROOT_CMAKE_TO_BIN_DIR}\" REALPATH)
++# resolve relative paths to absolute system paths
++get_filename_component(ROOT_BINDIR \"\${_ROOT_BINDIR}\" REALPATH)
+ ")
+ # Deprecated value ROOT_BINARY_DIR
+ set(ROOT_BINARY_DIR_SETUP "
+ # Deprecated value, please don't use it and use ROOT_BINDIR instead.
+-get_filename_component(ROOT_BINARY_DIR \"\${ROOT_BINDIR}\" ABSOLUTE)
++get_filename_component(ROOT_BINARY_DIR \"\${ROOT_BINDIR}\" REALPATH)
+ ")
+ 
+ # used by ROOTConfig.cmake from the build directory

Copied: root/repos/community-testing-x86_64/root.pc.tpl (from rev 610154, root/trunk/root.pc.tpl)
===================================================================
--- community-testing-x86_64/root.pc.tpl	                        (rev 0)
+++ community-testing-x86_64/root.pc.tpl	2020-04-02 17:10:25 UTC (rev 610155)
@@ -0,0 +1,12 @@
+prefix=_PREFIX
+exec_prefix=_EXECPREFIX
+libdir=_LIBDIR
+includedir=_INCDIR
+
+Name: ROOT
+Description: C++ data analysis framework and interpreter from CERN
+Version: _PKGVERSION
+URL: _UPSTREAM_URL
+Requires: _REQUIRES
+Libs: _LIBRARIES
+Cflags: _CFLAGS

Copied: root/repos/community-testing-x86_64/root.xml (from rev 610154, root/trunk/root.xml)
===================================================================
--- community-testing-x86_64/root.xml	                        (rev 0)
+++ community-testing-x86_64/root.xml	2020-04-02 17:10:25 UTC (rev 610155)
@@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<mime-info xmlns="http://www.freedesktop.org/standards/shared-mime-info">
+  <mime-type type="application/x-root">
+    <comment>ROOT file</comment>
+    <comment xml:lang="de">ROOT-Datei</comment>
+    <comment xml:lang="en">ROOT-File</comment>
+    <comment xml:lang="fr">ROOT-Fichier</comment>
+    <comment xml:lang="it">ROOT-File</comment>
+    <glob pattern="*.root"/>
+    <magic priority="80">
+      <match value="root" type="string" offset="0:64"/>
+    </magic>
+  </mime-type>
+</mime-info>

Copied: root/repos/community-testing-x86_64/settings-cuda.cmake (from rev 610154, root/trunk/settings-cuda.cmake)
===================================================================
--- community-testing-x86_64/settings-cuda.cmake	                        (rev 0)
+++ community-testing-x86_64/settings-cuda.cmake	2020-04-02 17:10:25 UTC (rev 610155)
@@ -0,0 +1,100 @@
+set (CMAKE_BUILD_TYPE Release CACHE STRING "" FORCE)
+set (BUILD_SHARED_LIBS ON CACHE BOOL "" FORCE)
+set (CMAKE_INSTALL_PREFIX /usr CACHE PATH "" FORCE)
+set (CMAKE_INSTALL_CMAKEDIR /usr/lib/cmake/ROOT CACHE PATH "" FORCE)
+set (CMAKE_INSTALL_BINDIR /usr/bin CACHE PATH "" FORCE)
+set (CMAKE_INSTALL_LIBDIR /usr/lib/root CACHE PATH "" FORCE)
+set (CMAKE_INSTALL_INCLUDEDIR /usr/include CACHE PATH "" FORCE)
+set (CMAKE_INSTALL_SYSCONFDIR /etc/root CACHE PATH "" FORCE)
+set (CMAKE_INSTALL_DATAROOTDIR /usr/share CACHE PATH "" FORCE)
+set (CMAKE_CXX_STANDARD 14 CACHE STRING "" FORCE)
+set (alien OFF CACHE BOOL "" FORCE)
+set (all OFF CACHE BOOL "" FORCE)
+set (asimage ON CACHE BOOL "" FORCE)
+set (builtin_afterimage OFF CACHE BOOL "" FORCE)
+set (builtin_clang ON CACHE BOOL "" FORCE)
+set (CLANG_ENABLE_STATIC_ANALYZER ON CACHE BOOL "" FORCE)
+set (CLANG_ANALYZER_BUILD_Z3 ON CACHE BOOL "" FORCE)
+set (builtin_cfitsio OFF CACHE BOOL "" FORCE)
+set (builtin_davix OFF CACHE BOOL "" FORCE)
+set (builtin_fftw3 OFF CACHE BOOL "" FORCE)
+set (builtin_ftgl OFF CACHE BOOL "" FORCE)
+set (builtin_freetype OFF CACHE BOOL "" FORCE)
+set (builtin_gl2ps OFF CACHE BOOL "" FORCE)
+set (builtin_glew OFF CACHE BOOL "" FORCE)
+set (builtin_gsl OFF CACHE BOOL "" FORCE)
+set (builtin_lzma OFF CACHE BOOL "" FORCE)
+set (builtin_llvm ON CACHE BOOL "" FORCE)
+set (builtin_openssl OFF CACHE BOOL "" FORCE)
+set (builtin_pcre OFF CACHE BOOL "" FORCE)
+set (builtin_tbb OFF CACHE BOOL "" FORCE)
+set (builtin_unuran OFF CACHE BOOL "" FORCE)
+set (builtin_vc OFF CACHE BOOL "" FORCE)
+set (builtin_xxhash OFF CACHE BOOL "" FORCE)
+set (builtin_xrootd OFF CACHE BOOL "" FORCE)
+set (builtin_zlib OFF CACHE BOOL "" FORCE)
+set (ccache ON CACHE BOOL "" FORCE)
+set (clad ON CACHE BOOL "" FORCE)
+set (cocoa OFF CACHE BOOL "" FORCE)  # MacOS only
+set (cuda ON CACHE BOOL "" FORCE)
+set (davix OFF CACHE BOOL "" FORCE)
+set (dcache OFF CACHE BOOL "" FORCE)
+set (exceptions ON CACHE BOOL "" FORCE)
+set (fail-on-missing ON CACHE BOOL "" FORCE)
+set (fftw3 ON CACHE BOOL "" FORCE)
+set (fitsio ON CACHE BOOL "" FORCE)
+set (fortran ON CACHE BOOL "" FORCE)
+set (gdml ON CACHE BOOL "" FORCE)
+set (genvector ON CACHE BOOL "" FORCE)
+set (gfal OFF CACHE BOOL "" FORCE)
+set (gl2ps ON CACHE BOOL "" FORCE)
+set (gminimal OFF CACHE BOOL "" FORCE)
+set (gnuinstall ON CACHE BOOL "" FORCE)
+set (gsl_shared ON CACHE BOOL "" FORCE)
+set (gviz ON CACHE BOOL "" FORCE)
+set (http ON CACHE BOOL "" FORCE)
+set (imt ON CACHE BOOL "" FORCE)
+set (jemalloc OFF CACHE BOOL "" FORCE)
+set (mathmore ON CACHE BOOL "" FORCE)
+set (minimal OFF CACHE BOOL "" FORCE)
+set (minuit2 ON CACHE BOOL "" FORCE)
+set (mlp ON CACHE BOOL "" FORCE)
+set (monalisa OFF CACHE BOOL "" FORCE)
+set (mpi ON CACHE BOOL "" FORCE)
+set (mt ON CACHE BOOL "" FORCE)
+set (mysql ON CACHE BOOL "" FORCE)
+set (odbc ON CACHE BOOL "" FORCE)
+set (opengl ON CACHE BOOL "" FORCE)
+set (OpenGL_GL_PREFERENCE GLVND CACHE STRING "" FORCE)  # use new policy since 3.11
+set (oracle OFF CACHE BOOL "" FORCE)
+set (pgsql ON CACHE BOOL "" FORCE)
+set (pythia6 OFF CACHE BOOL "" FORCE)
+set (pythia6_nolink OFF CACHE BOOL "" FORCE)
+set (pythia8 ON CACHE BOOL "" FORCE)
+set (pyroot ON CACHE BOOL "" FORCE)
+set (roofit ON CACHE BOOL "" FORCE)
+set (root7 ON CACHE BOOL "" FORCE)
+set (roottest OFF CACHE BOOL "" FORCE)
+set (rpath OFF CACHE BOOL "" FORCE)
+set (runtime_cxxmodules OFF CACHE BOOL "" FORCE)  # breaks python
+set (r OFF CACHE BOOL "" FORCE)  # requires r-rcpp
+set (shadowpw ON CACHE BOOL "" FORCE)
+set (shared ON CACHE BOOL "" FORCE)
+set (soversion OFF CACHE BOOL "" FORCE)
+set (spectrum ON CACHE BOOL "" FORCE)
+set (sqlite ON CACHE BOOL "" FORCE)
+set (ssl ON CACHE BOOL "" FORCE)
+set (tbb ON CACHE BOOL "" FORCE)
+set (tcmalloc OFF CACHE BOOL "" FORCE)
+set (testing OFF CACHE BOOL "" FORCE)
+set (tmva ON CACHE BOOL "" FORCE)
+set (tmva-cpu OFF CACHE BOOL "" FORCE)
+set (tmva-gpu ON CACHE BOOL "" FORCE)
+set (tmva-pymva ON CACHE BOOL "" FORCE)
+set (unuran ON CACHE BOOL "" FORCE)
+set (vc ON CACHE BOOL "" FORCE)
+set (vdt ON CACHE BOOL "" FORCE)
+set (winrtdebug OFF CACHE BOOL "" FORCE)  # windows only
+set (x11 ON CACHE BOOL "" FORCE)
+set (xml ON CACHE BOOL "" FORCE)
+set (xrootd ON CACHE BOOL "" FORCE)

Copied: root/repos/community-testing-x86_64/settings.cmake (from rev 610154, root/trunk/settings.cmake)
===================================================================
--- community-testing-x86_64/settings.cmake	                        (rev 0)
+++ community-testing-x86_64/settings.cmake	2020-04-02 17:10:25 UTC (rev 610155)
@@ -0,0 +1,99 @@
+set (CMAKE_BUILD_TYPE Release CACHE STRING "" FORCE)
+set (BUILD_SHARED_LIBS ON CACHE BOOL "" FORCE)
+set (CMAKE_INSTALL_PREFIX /usr CACHE PATH "" FORCE)
+set (CMAKE_INSTALL_CMAKEDIR /usr/lib/cmake/ROOT CACHE PATH "" FORCE)
+set (CMAKE_INSTALL_BINDIR /usr/bin CACHE PATH "" FORCE)
+set (CMAKE_INSTALL_LIBDIR /usr/lib/root CACHE PATH "" FORCE)
+set (CMAKE_INSTALL_INCLUDEDIR /usr/include CACHE PATH "" FORCE)
+set (CMAKE_INSTALL_SYSCONFDIR /etc/root CACHE PATH "" FORCE)
+set (CMAKE_INSTALL_DATAROOTDIR /usr/share CACHE PATH "" FORCE)
+set (CMAKE_CXX_STANDARD 17 CACHE STRING "" FORCE)
+set (alien OFF CACHE BOOL "" FORCE)
+set (all OFF CACHE BOOL "" FORCE)
+set (asimage ON CACHE BOOL "" FORCE)
+set (builtin_afterimage OFF CACHE BOOL "" FORCE)
+set (builtin_clang ON CACHE BOOL "" FORCE)
+set (CLANG_ENABLE_STATIC_ANALYZER ON CACHE BOOL "" FORCE)
+set (CLANG_ANALYZER_BUILD_Z3 ON CACHE BOOL "" FORCE)
+set (builtin_cfitsio OFF CACHE BOOL "" FORCE)
+set (builtin_davix OFF CACHE BOOL "" FORCE)
+set (builtin_fftw3 OFF CACHE BOOL "" FORCE)
+set (builtin_ftgl OFF CACHE BOOL "" FORCE)
+set (builtin_freetype OFF CACHE BOOL "" FORCE)
+set (builtin_gl2ps OFF CACHE BOOL "" FORCE)
+set (builtin_glew OFF CACHE BOOL "" FORCE)
+set (builtin_gsl OFF CACHE BOOL "" FORCE)
+set (builtin_lzma OFF CACHE BOOL "" FORCE)
+set (builtin_llvm ON CACHE BOOL "" FORCE)
+set (builtin_openssl OFF CACHE BOOL "" FORCE)
+set (builtin_pcre OFF CACHE BOOL "" FORCE)
+set (builtin_tbb OFF CACHE BOOL "" FORCE)
+set (builtin_unuran OFF CACHE BOOL "" FORCE)
+set (builtin_vc OFF CACHE BOOL "" FORCE)
+set (builtin_xxhash OFF CACHE BOOL "" FORCE)
+set (builtin_xrootd OFF CACHE BOOL "" FORCE)
+set (builtin_zlib OFF CACHE BOOL "" FORCE)
+set (ccache ON CACHE BOOL "" FORCE)
+set (clad ON CACHE BOOL "" FORCE)
+set (cocoa OFF CACHE BOOL "" FORCE)  # MacOS only
+set (cuda OFF CACHE BOOL "" FORCE)
+set (davix OFF CACHE BOOL "" FORCE)
+set (dcache OFF CACHE BOOL "" FORCE)
+set (exceptions ON CACHE BOOL "" FORCE)
+set (fail-on-missing ON CACHE BOOL "" FORCE)
+set (fftw3 ON CACHE BOOL "" FORCE)
+set (fitsio ON CACHE BOOL "" FORCE)
+set (fortran ON CACHE BOOL "" FORCE)
+set (gdml ON CACHE BOOL "" FORCE)
+set (genvector ON CACHE BOOL "" FORCE)
+set (gfal OFF CACHE BOOL "" FORCE)
+set (gl2ps ON CACHE BOOL "" FORCE)
+set (gminimal OFF CACHE BOOL "" FORCE)
+set (gnuinstall ON CACHE BOOL "" FORCE)
+set (gsl_shared ON CACHE BOOL "" FORCE)
+set (gviz ON CACHE BOOL "" FORCE)
+set (http ON CACHE BOOL "" FORCE)
+set (imt ON CACHE BOOL "" FORCE)
+set (jemalloc OFF CACHE BOOL "" FORCE)
+set (mathmore ON CACHE BOOL "" FORCE)
+set (minimal OFF CACHE BOOL "" FORCE)
+set (minuit2 ON CACHE BOOL "" FORCE)
+set (mlp ON CACHE BOOL "" FORCE)
+set (monalisa OFF CACHE BOOL "" FORCE)
+set (mpi ON CACHE BOOL "" FORCE)
+set (mt ON CACHE BOOL "" FORCE)
+set (mysql ON CACHE BOOL "" FORCE)
+set (odbc ON CACHE BOOL "" FORCE)
+set (opengl ON CACHE BOOL "" FORCE)
+set (OpenGL_GL_PREFERENCE GLVND CACHE STRING "" FORCE)  # use new policy since 3.11
+set (oracle OFF CACHE BOOL "" FORCE)
+set (pgsql ON CACHE BOOL "" FORCE)
+set (pythia6 OFF CACHE BOOL "" FORCE)
+set (pythia6_nolink OFF CACHE BOOL "" FORCE)
+set (pythia8 ON CACHE BOOL "" FORCE)
+set (pyroot ON CACHE BOOL "" FORCE)
+set (roofit ON CACHE BOOL "" FORCE)
+set (root7 ON CACHE BOOL "" FORCE)
+set (roottest OFF CACHE BOOL "" FORCE)
+set (rpath OFF CACHE BOOL "" FORCE)
+set (runtime_cxxmodules OFF CACHE BOOL "" FORCE)  # breaks python
+set (r OFF CACHE BOOL "" FORCE)  # requires r-rcpp
+set (shadowpw ON CACHE BOOL "" FORCE)
+set (shared ON CACHE BOOL "" FORCE)
+set (soversion OFF CACHE BOOL "" FORCE)
+set (spectrum ON CACHE BOOL "" FORCE)
+set (sqlite ON CACHE BOOL "" FORCE)
+set (ssl ON CACHE BOOL "" FORCE)
+set (tbb ON CACHE BOOL "" FORCE)
+set (tcmalloc OFF CACHE BOOL "" FORCE)
+set (testing OFF CACHE BOOL "" FORCE)
+set (tmva ON CACHE BOOL "" FORCE)
+set (tmva-cpu ON CACHE BOOL "" FORCE)
+set (tmva-pymva ON CACHE BOOL "" FORCE)
+set (unuran ON CACHE BOOL "" FORCE)
+set (vc ON CACHE BOOL "" FORCE)
+set (vdt ON CACHE BOOL "" FORCE)
+set (winrtdebug OFF CACHE BOOL "" FORCE)  # windows only
+set (x11 ON CACHE BOOL "" FORCE)
+set (xml ON CACHE BOOL "" FORCE)
+set (xrootd ON CACHE BOOL "" FORCE)


More information about the arch-commits mailing list