[arch-commits] Commit in haskell-http2/repos (2 files)

[Felix Yan]

    Date: Friday, April 3, 2020 @ 01:52:33
  Author: felixonmars
Revision: 610645

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-http2/repos/community-staging-x86_64/
  haskell-http2/repos/community-staging-x86_64/PKGBUILD
    (from rev 610644, haskell-http2/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: haskell-http2/repos/community-staging-x86_64/PKGBUILD (from rev 610644, haskell-http2/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-04-03 01:52:33 UTC (rev 610645)
@@ -0,0 +1,47 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=http2
+pkgname=haskell-http2
+pkgver=2.0.3
+pkgrel=70
+pkgdesc="HTTP/2 library"
+url="https://github.com/kazu-yamamoto/http2"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-case-insensitive' 'haskell-http-types' 'haskell-network'
+         'haskell-network-byte-order' 'haskell-psqueues' 'haskell-time-manager')
+makedepends=('ghc' 'haskell-aeson' 'haskell-aeson-pretty' 'haskell-base16-bytestring'
+             'haskell-doctest' 'haskell-glob' 'haskell-hspec' 'haskell-unordered-containers'
+             'haskell-vector')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('ff5f02c355f9f5c459d94993f05636955f81b91cbdbd4e8c262b56e1fa3846f92aff946f8ec6851ab57ffbb73afb42999cb3597eb250a9e15a8d6788da860b20')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-devel
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}