[arch-commits] Commit in haskell-insert-ordered-containers/repos (2 files)

[Felix Yan]

    Date: Friday, April 3, 2020 @ 01:53:32
  Author: felixonmars
Revision: 610647

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-insert-ordered-containers/repos/community-staging-x86_64/
  haskell-insert-ordered-containers/repos/community-staging-x86_64/PKGBUILD
    (from rev 610646, haskell-insert-ordered-containers/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: haskell-insert-ordered-containers/repos/community-staging-x86_64/PKGBUILD (from rev 610646, haskell-insert-ordered-containers/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-04-03 01:53:32 UTC (rev 610647)
@@ -0,0 +1,49 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=insert-ordered-containers
+pkgname=haskell-insert-ordered-containers
+pkgver=0.2.3
+pkgrel=24
+pkgdesc="Associative containers retating insertion order for traversals."
+url="https://github.com/phadej/insert-ordered-containers"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-base-compat' 'haskell-hashable' 'haskell-lens'
+         'haskell-optics-core' 'haskell-optics-extra' 'haskell-semigroupoids'
+         'haskell-unordered-containers')
+makedepends=('ghc' 'haskell-quickcheck' 'haskell-tasty' 'haskell-tasty-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('ed1bf7dfd2b432abf0b9344dd3a79485c19084b03a66088c3b0527e73f728f3acad67dde008815b4987006685a0b3ca0f4c07f29a6a2f06a63e8f98a0a932403')
+
+prepare() {
+    sed -e '/semigroups/d' -e 's/< *4.19/<5/' -e 's/< *2.14/<3/' \
+        -i ${_hkgname}-${pkgver}/${_hkgname}.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}