[arch-commits] Commit in gst-plugins-bad/repos (2 files)

[Maxime Gauduin]

    Date: Friday, April 3, 2020 @ 10:44:42
  Author: alucryd
Revision: 379238

archrelease: copy trunk to staging-x86_64

Added:
  gst-plugins-bad/repos/staging-x86_64/
  gst-plugins-bad/repos/staging-x86_64/PKGBUILD
    (from rev 379237, gst-plugins-bad/trunk/PKGBUILD)

----------+
 PKGBUILD |  102 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 102 insertions(+)

Copied: gst-plugins-bad/repos/staging-x86_64/PKGBUILD (from rev 379237, gst-plugins-bad/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2020-04-03 10:44:42 UTC (rev 379238)
@@ -0,0 +1,102 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgbase=gst-plugins-bad
+pkgname=(gst-plugins-bad-libs gst-plugins-bad)
+pkgver=1.16.2
+pkgrel=6
+pkgdesc="GStreamer open-source multimedia framework bad plugins"
+url="https://gstreamer.freedesktop.org/"
+arch=(x86_64)
+license=(LGPL)
+depends=(gst-plugins-base-libs orc libdrm libx11 libgudev libusb libvdpau)
+makedepends=(mjpegtools curl chromaprint libmms faad2 libdca libdvdnav
+             libmodplug libgme nettle libkate wayland libofa openjpeg2 libwebp
+             libsrtp sbc rtmpdump libexif libdvdread wildmidi ladspa openal
+             vulkan-icd-loader libfdk-aac faac soundtouch spandsp neon
+             webrtc-audio-processing libdc1394 libmpcdec zvbi openexr libbs2b
+             libnice lcms2 bluez-libs glu srt aom x265 liblrdf libde265 zbar
+             librsvg fluidsynth lilv lv2 gst-plugins-good python gtk-doc git
+             gobject-introspection vulkan-headers vulkan-validation-layers
+             wayland-protocols gtk3 meson)
+checkdepends=(xorg-server-xvfb)
+options=(!emptydirs)
+_commit=a6f26408f74a60d02ce6b4f0daee392ce847055f  # tags/1.16.2^0
+source=("git+https://gitlab.freedesktop.org/gstreamer/gst-plugins-bad.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgbase
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgbase
+}
+
+build() {
+  arch-meson $pkgbase build \
+    -D directfb=disabled \
+    -D flite=disabled \
+    -D gsm=disabled \
+    -D iqa=disabled \
+    -D msdk=disabled \
+    -D nvdec=disabled \
+    -D nvenc=disabled \
+    -D opencv=disabled \
+    -D openh264=disabled \
+    -D openmpt=disabled \
+    -D openni2=disabled \
+    -D opensles=disabled \
+    -D sctp=disabled \
+    -D tinyalsa=disabled \
+    -D voaacenc=disabled \
+    -D voamrwbenc=disabled \
+    -D wasapi=disabled \
+    -D wpe=disabled \
+    -D gobject-cast-checks=disabled \
+    -D glib-asserts=disabled \
+    -D glib-checks=disabled \
+    -D package-name="GStreamer Bad Plugins (Arch Linux)" \
+    -D package-origin="https://www.archlinux.org/"
+  ninja -C build
+}
+
+check() (
+  mkdir -p -m 700 "${XDG_RUNTIME_DIR:=$PWD/runtime-dir}"
+  export XDG_RUNTIME_DIR
+
+  xvfb-run -s '-screen 0 1920x1080x24 -nolisten local +iglx -noreset' \
+    meson test -C build --print-errorlogs
+)
+
+package_gst-plugins-bad-libs() {
+  pkgdesc="${pkgdesc/plugins/libraries}"
+
+  DESTDIR="$pkgdir" meson install -C build
+
+  mkdir -p ext/lib/gstreamer-1.0
+  for _x in aom assrender bs2b bz2 chromaprint closedcaption colormanagement \
+            curl dashdemux dc1394 de265 dtls dtsdec faac faad fdkaac \
+            fluidsynthmidi gme hls kate ladspa lv2 mms modplug mpeg2enc mplex \
+            musepack neonhttpsrc ofa openal openexr openjpeg opusparse \
+            resindvd rsvg rtmp sbc smoothstreaming sndfile soundtouch spandsp \
+            srt srtp teletext ttmlsubs vulkan waylandsink webp webrtc \
+            webrtcdsp wildmidi x265 zbar; do
+    _x="lib/gstreamer-1.0/libgst${_x}.so"
+    mv "$pkgdir/usr/$_x" "ext/$_x"
+  done
+}
+
+package_gst-plugins-bad() {
+  depends=("gst-plugins-bad-libs=$pkgver" gst-plugins-good
+           aom libass libbs2b bzip2 chromaprint pango lcms2 curl libxml2
+           libdc1394 libde265 openssl libdca faac faad2 libfdk-aac fluidsynth
+           libgme nettle libkate liblrdf lilv libmms libmodplug mjpegtools
+           libmpcdec neon libofa openal openexr openjpeg2 opus libdvdnav
+           libdvdread librsvg rtmpdump sbc libsndfile soundtouch spandsp srt
+           libsrtp zvbi vulkan-icd-loader libxcb wayland libwebp libnice
+           webrtc-audio-processing wildmidi x265 zbar)
+
+  mv ext "$pkgdir/usr"
+}