[arch-commits] Commit in paraview/repos (2 files)

[Bruno Pagani]

    Date: Sunday, April 5, 2020 @ 20:45:42
  Author: archange
Revision: 611985

archrelease: copy trunk to community-staging-x86_64

Added:
  paraview/repos/community-staging-x86_64/
  paraview/repos/community-staging-x86_64/PKGBUILD
    (from rev 611984, paraview/trunk/PKGBUILD)

----------+
 PKGBUILD |   62 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)

Copied: paraview/repos/community-staging-x86_64/PKGBUILD (from rev 611984, paraview/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-04-05 20:45:42 UTC (rev 611985)
@@ -0,0 +1,62 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Maintainer: Mathieu Westphal <mathieu.westphal at kitware.com>
+# Contributor: Stéphane Gaudreault <stephane at archlinux.org>
+# Contributor: <xantares09 at hotmail.com>
+
+_pkg=paraview
+_mpi=openmpi
+pkgname=${_pkg}
+#-${_mpi}
+pkgver=5.8.0
+pkgrel=2
+pkgdesc="Parallel Visualization application using VTK (${_mpi} version)"
+arch=(x86_64)
+url="https://www.paraview.org"
+license=(BSD custom)
+depends=(boost-libs qt5-tools qt5-x11extras qt5-svg intel-tbb openmpi ffmpeg
+         ospray python-numpy cgns protobuf
+         double-conversion expat freetype2 gdal glew hdf5 libjpeg jsoncpp
+         libjsoncpp.so libxml2 lz4 xz python-mpi4py netcdf libogg libpng pdal
+         pugixml libtheora libtiff zlib)
+#        gl2ps
+#        libharu
+optdepends=(python-matplotlib)
+makedepends=(cmake boost mesa gcc-fortran ninja qt5-tools qt5-xmlpatterns eigen pegtl utf8cpp)
+source=("${url}/files/v${pkgver:0:3}/ParaView-v${pkgver/R/-R}.tar.xz")
+sha256sums=('219e4107abf40317ce054408e9c3b22fb935d464238c1c00c0161f1c8697a3f9')
+
+build() {
+    # Note regarding use of system dependencies:
+    # GL2PS has non-upstreamed patches
+    # LIBHARU blocked by https://github.com/libharu/libharu/pull/157
+    cmake -B build -S ParaView-v${pkgver/R/-R} \
+        -DCMAKE_BUILD_TYPE=Release \
+        -DCMAKE_INSTALL_PREFIX=/usr \
+        -DPARAVIEW_ENABLE_FFMPEG=ON \
+        -DPARAVIEW_ENABLE_GDAL=ON \
+        -DPARAVIEW_ENABLE_MOTIONFX=ON \
+        -DPARAVIEW_ENABLE_PDAL=ON \
+        -DPARAVIEW_ENABLE_VISITBRIDGE=ON \
+        -DPARAVIEW_ENABLE_XDMF3=ON \
+        -DPARAVIEW_INSTALL_DEVELOPMENT_FILES=ON \
+        -DPARAVIEW_USE_MPI=ON \
+        -DPARAVIEW_USE_PYTHON=ON \
+        -DPARAVIEW_USE_RAYTRACING=ON \
+        -DPARAVIEW_BUILD_WITH_EXTERNAL=ON \
+        -DVTK_MODULE_USE_EXTERNAL_VTK_gl2ps=OFF \
+        -DVTK_MODULE_USE_EXTERNAL_VTK_libharu=OFF \
+        -DVTK_SMP_IMPLEMENTATION_TYPE=TBB \
+        -DVTKm_ENABLE_MPI=ON \
+        -DVTK_MODULE_ENABLE_VTK_IOGDAL=YES \
+        -DVTK_MODULE_ENABLE_VTK_IOPDAL=YES \
+        -GNinja
+
+    ninja -C build ${MAKEFLAGS}
+}
+
+package() {
+    DESTDIR="${pkgdir}" ninja -C build install
+
+    # Install license
+    install -Dm644 ParaView-v${pkgver/R/-R}/License_v1.2.txt "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
+}