[arch-commits] Commit in waybar/repos (2 files)

[Brett Cornwall]

    Date: Monday, April 6, 2020 @ 06:32:04
  Author: ainola
Revision: 612033

archrelease: copy trunk to community-staging-x86_64

Added:
  waybar/repos/community-staging-x86_64/
  waybar/repos/community-staging-x86_64/PKGBUILD
    (from rev 612032, waybar/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: waybar/repos/community-staging-x86_64/PKGBUILD (from rev 612032, waybar/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-04-06 06:32:04 UTC (rev 612033)
@@ -0,0 +1,44 @@
+# Maintainer: Brett Cornwall <ainola at archlinux.org>
+
+pkgname=waybar
+pkgver=0.9.1
+pkgrel=3
+pkgdesc='Highly customizable Wayland bar for Sway and Wlroots based compositors'
+arch=('x86_64')
+url="https://github.com/Alexays/Waybar/"
+license=('MIT')
+depends=(
+    'chrono-date'
+    'gtk-layer-shell'
+    'gtkmm3'
+    'libjsoncpp.so'
+    'libspdlog.so'
+    'libdbusmenu-gtk3'
+    'libpulse'
+    'libmpdclient'
+)
+makedepends=(
+    'cmake'
+    'meson'
+    'scdoc'  # For generating manpages
+    'sway'  # Support for workspace and window title modules
+)
+optdepends=(
+    'otf-font-awesome: Icons in the default configuration'
+)
+source=(
+    "$pkgname-$pkgver.tar.gz::https://github.com/Alexays/Waybar/archive/$pkgver.tar.gz"
+)
+sha256sums=('97d61baced26835b49d9366a1316925fc5ec59c4ae9269d85c71c5375a061478')
+
+build() {
+    cd "Waybar-$pkgver"
+    meson --prefix=/usr --wrap-mode=nofallback build
+    ninja -C build
+}
+
+package() {
+    cd "Waybar-$pkgver"
+    DESTDIR="$pkgdir" ninja -C build install
+    install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
+}