[arch-commits] Commit in git-repair/repos (2 files)

Felix Yan felixonmars at archlinux.org
Mon Apr 6 21:42:04 UTC 2020


    Date: Monday, April 6, 2020 @ 21:42:03
  Author: felixonmars
Revision: 612158

archrelease: copy trunk to community-staging-x86_64

Added:
  git-repair/repos/community-staging-x86_64/
  git-repair/repos/community-staging-x86_64/PKGBUILD
    (from rev 612157, git-repair/trunk/PKGBUILD)

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Copied: git-repair/repos/community-staging-x86_64/PKGBUILD (from rev 612157, git-repair/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-04-06 21:42:03 UTC (rev 612158)
@@ -0,0 +1,38 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=git-repair
+pkgver=1.20200102
+pkgrel=64
+pkgdesc="Repairs a damaged git repository"
+url="https://git-repair.branchable.com/"
+license=("AGPL3")
+arch=('x86_64')
+depends=('git' 'ghc-libs' 'haskell-async' 'haskell-attoparsec' 'haskell-data-default'
+         'haskell-exceptions' 'haskell-filepath-bytestring' 'haskell-hslogger' 'haskell-ifelse'
+         'haskell-network' 'haskell-network-uri' 'haskell-optparse-applicative' 'haskell-quickcheck'
+         'haskell-split' 'haskell-unix-compat' 'haskell-utf8-string')
+makedepends=('ghc')
+source=("$pkgname::git://git-repair.branchable.com/#tag=$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+  cd git-repair
+  sed -i 's/ fail / error /' Utility/HumanTime.hs
+}
+
+build() {
+  cd git-repair
+
+  runhaskell Setup configure -O --prefix=/usr --enable-executable-dynamic --disable-library-vanilla \
+    --docdir="/usr/share/doc/$pkgname" --ghc-option='-pie'
+  runhaskell Setup build
+}
+
+package() {
+  cd git-repair
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -Dm644 git-repair.1 "$pkgdir"/usr/share/man/man1/git-repair.1
+
+  rm "$pkgdir"/usr/share/doc/git-repair/COPYRIGHT
+  rmdir "$pkgdir"/usr/share/doc/git-repair "$pkgdir"/usr/share/doc
+}


More information about the arch-commits mailing list