[arch-commits] Commit in gobject-introspection/repos (2 files)

[Felix Yan]

    Date: Wednesday, April 8, 2020 @ 16:37:22
  Author: felixonmars
Revision: 379850

archrelease: copy trunk to staging-x86_64

Added:
  gobject-introspection/repos/staging-x86_64/
  gobject-introspection/repos/staging-x86_64/PKGBUILD
    (from rev 379849, gobject-introspection/trunk/PKGBUILD)

----------+
 PKGBUILD |   62 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)

Copied: gobject-introspection/repos/staging-x86_64/PKGBUILD (from rev 379849, gobject-introspection/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2020-04-08 16:37:22 UTC (rev 379850)
@@ -0,0 +1,62 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+
+pkgbase=gobject-introspection
+pkgname=(gobject-introspection gobject-introspection-runtime)
+pkgver=1.64.1
+pkgrel=2
+pkgdesc="Introspection system for GObject-based libraries"
+url="https://wiki.gnome.org/Projects/GObjectIntrospection"
+arch=(x86_64)
+license=(LGPL GPL)
+depends=(python-mako python-markdown)
+_glibver=2.64.1
+makedepends=(cairo git gtk-doc python-sphinx meson "glib2=$_glibver")
+options=(!emptydirs)
+_commit=e315fd15bbf0f01e211684f6c1de1bf4300d91b5  # tags/1.64.1^0
+source=("git+https://gitlab.gnome.org/GNOME/gobject-introspection.git#commit=$_commit"
+        "git+https://gitlab.gnome.org/GNOME/glib.git?signed#tag=$_glibver")
+sha512sums=('SKIP'
+            'SKIP')
+validpgpkeys=('923B7025EE03C1C59F42684CF0942E894B2EAFA0') # Philip Withnall <philip at tecnocode.co.uk>
+
+pkgver() {
+  cd $pkgbase
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgbase
+}
+  
+build() {
+  arch-meson $pkgbase build \
+    -D gtk_doc=true \
+    -D glib_src_dir="$srcdir/glib"
+  ninja -C build
+}
+
+check() {
+  meson test -C build
+}
+
+package_gobject-introspection() {
+  depends+=("gobject-introspection-runtime=$pkgver-$pkgrel")
+
+  DESTDIR="$pkgdir" meson install -C build
+
+  python -m compileall -d /usr/lib/$pkgbase "$pkgdir/usr/lib/$pkgbase"
+  python -O -m compileall -d /usr/lib/$pkgbase "$pkgdir/usr/lib/$pkgbase"
+
+### Split runtime
+  mkdir -p "$srcdir/runtime/lib"
+  mv "$pkgdir"/usr/lib/{lib*,girepository-*} "$srcdir/runtime/lib"
+}
+
+package_gobject-introspection-runtime() {
+  pkgdesc+=" (runtime library)"
+  depends=(glib2)
+  provides+=(libgirepository-1.0.so)
+
+  mv "$srcdir/runtime" "$pkgdir/usr"
+}