[arch-commits] Commit in lib32-wayland/repos (2 files)

[Evangelos Foutras]

    Date: Wednesday, April 8, 2020 @ 22:52:47
  Author: foutrelis
Revision: 612807

archrelease: copy trunk to multilib-staging-x86_64

Added:
  lib32-wayland/repos/multilib-staging-x86_64/
  lib32-wayland/repos/multilib-staging-x86_64/PKGBUILD
    (from rev 612806, lib32-wayland/trunk/PKGBUILD)

----------+
 PKGBUILD |   59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)

Copied: lib32-wayland/repos/multilib-staging-x86_64/PKGBUILD (from rev 612806, lib32-wayland/trunk/PKGBUILD)
===================================================================
--- multilib-staging-x86_64/PKGBUILD	                        (rev 0)
+++ multilib-staging-x86_64/PKGBUILD	2020-04-08 22:52:47 UTC (rev 612807)
@@ -0,0 +1,59 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Tom Gundersen <teg at jklm.no>
+# Contributor: Sébastien Luttringer <sеblu@аrchlіnux․org>
+# Contributor: Joel Teichroeb <joel at teichroeb.net>
+
+pkgname=lib32-wayland
+pkgver=1.18.0
+pkgrel=2
+pkgdesc='A computer display server protocol'
+arch=(x86_64)
+url=https://wayland.freedesktop.org
+license=(MIT)
+depends=(
+  lib32-glibc
+  lib32-libffi
+  lib32-expat
+  lib32-libxml2
+  wayland
+)
+makedepends=(git)
+source=(git+https://gitlab.freedesktop.org/wayland/wayland.git#tag=eb1339edd398b9f5328816931e585db4229aa132)
+sha256sums=(SKIP)
+
+pkgver() {
+  cd wayland
+
+  git describe --tags
+}
+
+prepare() {
+  cd wayland
+
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd wayland
+
+  export CC='gcc -m32'
+  export PKG_CONFIG_PATH=/usr/lib32/pkgconfig
+
+  ./configure \
+    --prefix=/usr \
+    --libdir=/usr/lib32 \
+    --disable-documentation \
+    --disable-static
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+package() {
+  make DESTDIR="${pkgdir}" -C wayland install
+  rm -rf "${pkgdir}"/usr/{bin,include,share}
+
+  install -dm 755 "${pkgdir}"/usr/share/licenses
+  ln -s wayland "${pkgdir}"/usr/share/licenses/lib32-wayland
+}
+
+# vim: ts=2 sw=2 et: