[arch-commits] Commit in (6 files)

[Felix Yan]

    Date: Thursday, April 9, 2020 @ 00:35:52
  Author: felixonmars
Revision: 612858

addpkg: netfilter-fullconenat r73.0cf3b48-6

Added:
  netfilter-fullconenat/
  netfilter-fullconenat/repos/
  netfilter-fullconenat/trunk/
  netfilter-fullconenat/trunk/Kbuild
  netfilter-fullconenat/trunk/PKGBUILD
  netfilter-fullconenat/trunk/netfilter-fullconenat.conf

----------------------------+
 Kbuild                     |    1 +
 PKGBUILD                   |   40 ++++++++++++++++++++++++++++++++++++++++
 netfilter-fullconenat.conf |    1 +
 3 files changed, 42 insertions(+)

Added: netfilter-fullconenat/trunk/Kbuild
===================================================================
--- netfilter-fullconenat/trunk/Kbuild	                        (rev 0)
+++ netfilter-fullconenat/trunk/Kbuild	2020-04-09 00:35:52 UTC (rev 612858)
@@ -0,0 +1 @@
+obj-m = xt_FULLCONENAT.o

Added: netfilter-fullconenat/trunk/PKGBUILD
===================================================================
--- netfilter-fullconenat/trunk/PKGBUILD	                        (rev 0)
+++ netfilter-fullconenat/trunk/PKGBUILD	2020-04-09 00:35:52 UTC (rev 612858)
@@ -0,0 +1,40 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Edward Pacman <edward at edward-p.xyz>
+
+pkgname=netfilter-fullconenat
+pkgver=r73.0cf3b48
+pkgrel=6
+pkgdesc="A kernel module that turns MASQUERADE into full cone SNAT"
+arch=('any')
+url="https://github.com/Chion82/netfilter-full-cone-nat"
+license=('GPL2')
+depends=("linux")
+makedepends=('linux-headers' 'git')
+source=("netfilter-fullconenat.conf" Kbuild
+        "${pkgname}::git+https://github.com/Chion82/netfilter-full-cone-nat.git")
+sha256sums=('a17dfdf1fd046219daeacc60065e3a81c80c2eb2cfdf6d8068278c509577f571'
+            '7ff12ad066a68c65f23fc7e01654ca459ce3458172e3dce30f42553fa44dd7c2'
+            'SKIP')
+
+pkgver() {
+  cd "$srcdir/${pkgname}"
+  ( set -o pipefail
+    git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
+    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+  )
+}
+
+build() {
+  cd $pkgname
+  ln -s ../Kbuild
+  make -C /usr/src/linux M=$PWD modules
+}
+
+package() {
+  # Install modules-load.conf
+  install -Dm644 netfilter-fullconenat.conf "${pkgdir}/usr/lib/modules-load.d/netfilter-fullconenat.conf"
+
+  install -Dt "${pkgdir}/usr/lib/modules/$(</usr/src/linux/version)/kernel/net/netfilter" -m644 \
+    $pkgname/*.ko
+  find "${pkgdir}" -name '*.ko' -exec gzip -n {} +
+}

Added: netfilter-fullconenat/trunk/netfilter-fullconenat.conf
===================================================================
--- netfilter-fullconenat/trunk/netfilter-fullconenat.conf	                        (rev 0)
+++ netfilter-fullconenat/trunk/netfilter-fullconenat.conf	2020-04-09 00:35:52 UTC (rev 612858)
@@ -0,0 +1 @@
+xt_FULLCONENAT