[arch-commits] Commit in pygobject2/repos (staging-x86_64 staging-x86_64/PKGBUILD)

Felix Yan felixonmars at archlinux.org
Thu Apr 9 01:04:38 UTC 2020


    Date: Thursday, April 9, 2020 @ 01:04:37
  Author: felixonmars
Revision: 379884

archrelease: copy trunk to staging-x86_64

Added:
  pygobject2/repos/staging-x86_64/
  pygobject2/repos/staging-x86_64/PKGBUILD
    (from rev 379883, pygobject2/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: pygobject2/repos/staging-x86_64/PKGBUILD (from rev 379883, pygobject2/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2020-04-09 01:04:37 UTC (rev 379884)
@@ -0,0 +1,44 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+
+pkgbase=pygobject2
+pkgname=(python2-gobject2)
+pkgver=2.28.7
+pkgrel=5
+pkgdesc="Legacy Python 2 bindings for GObject"
+url="https://wiki.gnome.org/Projects/PyGObject"
+arch=(x86_64)
+license=(LGPL)
+depends=(glib2 python2)
+makedepends=(git)
+provides=("pygobject2-devel=$pkgver-$pkgrel")
+conflicts=('pygobject2-devel')
+replaces=('pygobject2-devel<=2.28.7-3')
+_commit=c9594b6a91e6ca2086fedec2ed8249e0a9c029fc  # tags/PYGOBJECT_2_28_7^0
+source=("git+https://gitlab.gnome.org/GNOME/pygobject.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd pygobject
+  git describe --tags | sed 's/^PYGOBJECT_//;s/_/./g;s/-/+/g'
+}
+
+prepare() {
+  cd pygobject
+  find . \( -name '*.py' -o -name '*.py.in' \) -exec sed -i '1s|python$|&2|' {} +
+  autoreconf -fvi
+}
+
+build() (
+  cd pygobject
+  CPPFLAGS+=' -Wno-deprecated-declarations'
+  ./configure --prefix=/usr --disable-introspection PYTHON=/usr/bin/python2
+  sed -i 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+)
+
+package_python2-gobject2() {
+  cd pygobject
+  make DESTDIR="$pkgdir" install
+  rm -r "$pkgdir/usr/share/gtk-doc"
+}


More information about the arch-commits mailing list