[arch-commits] Commit in netcdf/repos (2 files)

[Bruno Pagani]

    Date: Friday, April 10, 2020 @ 23:43:49
  Author: archange
Revision: 613199

archrelease: copy trunk to community-staging-x86_64

Added:
  netcdf/repos/community-staging-x86_64/
  netcdf/repos/community-staging-x86_64/PKGBUILD
    (from rev 613198, netcdf/trunk/PKGBUILD)

----------+
 PKGBUILD |   41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

Copied: netcdf/repos/community-staging-x86_64/PKGBUILD (from rev 613198, netcdf/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-04-10 23:43:49 UTC (rev 613199)
@@ -0,0 +1,41 @@
+# Maintainer: Ronald van Haren <ronald.archlinux.org>
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Contributor: damir <damir at archlinux.org>
+
+pkgname=netcdf
+pkgver=4.7.4
+pkgrel=1
+pkgdesc="network Common Data Form interface for array-oriented data access and corresponding library"
+arch=(x86_64)
+url="https://www.unidata.ucar.edu/software/netcdf/"
+depends=(hdf5 curl)
+makedepends=(cmake)
+optdepends=('netcdf-fortran: fortran bindings' 'netcdf-cxx: c++ bindings')
+options=(!makeflags)
+license=(custom)
+source=(https://github.com/Unidata/netcdf-c/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha256sums=('99930ad7b3c4c1a8e8831fb061cb02b2170fc8e5ccaeda733bd99c3b9d31666b')
+
+build() {
+    cmake -B build -S ${pkgname}-c-${pkgver} \
+        -DCMAKE_INSTALL_PREFIX=/usr \
+        -DCMAKE_INSTALL_LIBDIR=lib \
+        -DCMAKE_BUILD_TYPE=Release \
+        -DENABLE_CDF5=ON \
+        -DENABLE_DAP_LONG_TESTS=ON \
+        -DENABLE_EXAMPLE_TESTS=ON \
+        -DENABLE_EXTRA_TESTS=ON \
+        -DENABLE_FAILING_TESTS=ON \
+        -DENABLE_FILTER_TESTING=ON \
+        -DENABLE_LARGE_FILE_TESTS=ON
+    make -C build
+}
+
+check() {
+    make -C build test
+}
+
+package() {
+    make -C build DESTDIR="${pkgdir}" install
+    install -Dm644 ${pkgname}-c-${pkgver}/COPYRIGHT -t "${pkgdir}"/usr/share/licenses/${pkgname}/
+}