[arch-commits] Commit in python-pytables/repos (2 files)

[Bruno Pagani]

    Date: Sunday, April 12, 2020 @ 15:08:33
  Author: archange
Revision: 613420

archrelease: copy trunk to community-staging-x86_64

Added:
  python-pytables/repos/community-staging-x86_64/
  python-pytables/repos/community-staging-x86_64/PKGBUILD
    (from rev 613419, python-pytables/trunk/PKGBUILD)

----------+
 PKGBUILD |   32 ++++++++++++++++++++++++++++++++
 1 file changed, 32 insertions(+)

Copied: python-pytables/repos/community-staging-x86_64/PKGBUILD (from rev 613419, python-pytables/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-04-12 15:08:33 UTC (rev 613420)
@@ -0,0 +1,32 @@
+# Maintainer: Andrzej Giniewicz <gginiu at gmail.com>
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Contributor: Sebastien Binet <binet at cern.ch>
+
+pkgname=python-pytables
+pkgver=3.6.1
+pkgrel=5
+pkgdesc="A package for managing hierarchical datasets and designed to efficiently and easily cope with extremely large amounts of data"
+arch=(x86_64)
+url="https://www.pytables.org"
+license=("BSD")
+depends=(blosc lzo hdf5 python-numexpr)
+makedepends=(python-setuptools cython)
+source=("https://github.com/PyTables/PyTables/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha256sums=('4cea86bab5bcb5423a07c7951b8c65e24b674e0dcec0e448d434829eff5f18d0')
+
+build() {
+  cd PyTables-${pkgver}
+  python setup.py build --blosc=/usr --lzo=/usr --hdf5=/usr --bzip2=/usr
+}
+
+check() {
+  local python_version=$(python -c 'import sys; print(".".join(map(str, sys.version_info[:2])))')
+  cd PyTables-${pkgver}/build/lib.linux-${CARCH}-${python_version}
+  PYTHONPATH="." python -m tables.tests.test_all  
+}
+
+package() {
+  cd PyTables-${pkgver}
+  python setup.py install --skip-build --prefix=/usr --root="${pkgdir}" --optimize=1
+  install -Dm644 LICENSE.txt -t "${pkgdir}"/usr/share/licenses/${pkgname}/
+}