[arch-commits] Commit in pnetcdf-openmpi/repos (2 files)

Bruno Pagani archange at archlinux.org
Sun Apr 12 18:56:43 UTC 2020


    Date: Sunday, April 12, 2020 @ 18:56:42
  Author: archange
Revision: 613457

archrelease: copy trunk to community-staging-x86_64

Added:
  pnetcdf-openmpi/repos/community-staging-x86_64/
  pnetcdf-openmpi/repos/community-staging-x86_64/PKGBUILD
    (from rev 613456, pnetcdf-openmpi/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: pnetcdf-openmpi/repos/community-staging-x86_64/PKGBUILD (from rev 613456, pnetcdf-openmpi/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-04-12 18:56:42 UTC (rev 613457)
@@ -0,0 +1,44 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+_pkg=pnetcdf
+_mpi=openmpi
+pkgname=${_pkg}-${_mpi}
+pkgver=1.12.1
+pkgrel=2
+pkgdesc="Parallel I/O Library for NetCDF File Access (${_mpi} version)"
+arch=(x86_64)
+url="https://parallel-netcdf.github.io/"
+license=(custom)
+depends=("${_mpi}" "netcdf-${_mpi}")
+makedepends=(gcc-fortran)
+checkdepends=(inetutils)
+provides=(parallel-netcdf parallel-netcdf-openmpi)
+conflicts=(parallel-netcdf parallel-netcdf-openmpi)
+replaces=(parallel-netcdf parallel-netcdf-openmpi)
+options=(staticlibs)
+source=("${url}/Release/${_pkg}-${pkgver}.tar.gz")
+sha1sums=('e92580824534f2563c6cad6e128e43c89519e03d')
+
+prepare() {
+    cd ${_pkg}-${pkgver}
+    autoreconf -vfi
+}
+
+build() {
+    cd ${_pkg}-${pkgver}
+    ./configure --prefix=/usr --enable-shared --enable-netcdf4
+    sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+    make LIBTOOLFLAGS=--verbose
+}
+
+check() {
+    cd ${_pkg}-${pkgver}
+    make check
+    make ptest
+}
+
+package() {
+    cd ${_pkg}-${pkgver}
+    make DESTDIR="${pkgdir}" install
+    install -Dm644 COPYRIGHT -t "${pkgdir}"/usr/share/licenses/${_pkg}
+}


More information about the arch-commits mailing list