[arch-commits] Commit in qtile/repos (community-x86_64 community-x86_64/PKGBUILD)

David Runge dvzrv at archlinux.org
Sun Apr 12 20:19:46 UTC 2020


    Date: Sunday, April 12, 2020 @ 20:19:45
  Author: dvzrv
Revision: 613472

archrelease: copy trunk to community-x86_64

Added:
  qtile/repos/community-x86_64/
  qtile/repos/community-x86_64/PKGBUILD
    (from rev 613471, qtile/trunk/PKGBUILD)

----------+
 PKGBUILD |   73 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 73 insertions(+)

Copied: qtile/repos/community-x86_64/PKGBUILD (from rev 613471, qtile/trunk/PKGBUILD)
===================================================================
--- community-x86_64/PKGBUILD	                        (rev 0)
+++ community-x86_64/PKGBUILD	2020-04-12 20:19:45 UTC (rev 613472)
@@ -0,0 +1,73 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+
+pkgname=qtile
+pkgver=0.15.0
+pkgrel=1
+pkgdesc="A full-featured, pure-Python tiling window manager"
+arch=('x86_64')
+url="http://www.qtile.org"
+license=('MIT')
+depends=('gdk-pixbuf2' 'pango' 'python-cffi' 'python-xcffib' 'python-cairocffi'
+'python-dbus' 'python-gobject' 'python-setuptools' 'python-six')
+makedepends=('jupyter_console' 'libpulse' 'python-ipykernel' 'python-iwlib'
+'python-keyring' 'python-psutil' 'python-pytest' 'python-xdg')
+optdepends=('alsa-utils: volume widget'
+            'canto-daemon: canto widget'
+            'cmus: cmus widget'
+            'khal: khal_calendar widget'
+            'libpulse: for pulse_volume and pulseaudio_ffi widget'
+            'lm_sensors: sensors widget'
+            'moc: moc widget'
+            'python-iwlib: wlan widget'
+            'python-keyring: imapwidget widget'
+            'python-mpd2: mpd2widget widget'
+            'python-psutil: graph, net and memory widget'
+            'python-setproctitle: change process name to qtile'
+            'python-xdg: launchbar widget')
+checkdepends=('imagemagick' 'python-pytest' 'python-xvfbwrapper' 'xorg-xcalc'
+'xorg-xclock' 'xorg-xeyes' 'xorg-server-xephyr' 'xorg-xrandr' 'xterm')
+source=("${pkgname}-${pkgver}.tar.gz::https://github.com/${pkgname}/${pkgname}/archive/v${pkgver}.tar.gz")
+sha512sums=('d8c94a40d158b680923d27e64eca790cc6d197d99ebc8e3cbd4beebf7e8802c69fc81d3840c5491d580b55e97180e10f06dce92d8cb054059b41c4b4c57c9819')
+
+build() {
+  cd "${pkgname}-${pkgver}"
+  python setup.py build
+}
+
+# # tests disabled for now, as the test suite won't return:
+# # https://github.com/qtile/qtile/issues/1130
+# # some tests are failing:
+# # https://github.com/qtile/qtile/issues/1352
+# check() {
+#   cd "${pkgname}-${pkgver}"
+#   export PYTTHONPATH="build/lib/:${PYTHONPATH}"
+#   export LC_TYPE=en_US.UTF-8
+#   ./scripts/ffibuild
+#   pytest -vv -k 'not test_images_good \
+#                  and not test_svg_scaling \
+#                  and not test_pattern_rotate \
+#                  and not test_pattern \
+#                  and not test_from_path \
+#                  and not test_init \
+#                  and not test_get_cairo_surface'
+# }
+
+package() {
+  cd "${pkgname}-${pkgver}"
+  # install
+  python setup.py install --skip-build \
+    --optimize=1 \
+    --root="${pkgdir}" \
+    --prefix=/usr
+  # license
+  install -vDm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}/"
+  # config
+  install -vDm 644 libqtile/resources/default_config.py \
+    -t "${pkgdir}/usr/share/doc/${pkgname}/"
+  # desktop file
+  install -vDm 644 "resources/${pkgname}.desktop" \
+    -t "${pkgdir}/usr/share/xsessions/"
+  # docs
+  install -t "${pkgdir}/usr/share/doc/${pkgname}/" \
+    -vDm 644 {CHANGELOG,README.rst}
+}


More information about the arch-commits mailing list