[arch-commits] Commit in python-netcdf4/repos (2 files)

Bruno Pagani archange at archlinux.org
Sun Apr 12 23:04:16 UTC 2020


    Date: Sunday, April 12, 2020 @ 23:04:15
  Author: archange
Revision: 613486

archrelease: copy trunk to community-staging-x86_64

Added:
  python-netcdf4/repos/community-staging-x86_64/
  python-netcdf4/repos/community-staging-x86_64/PKGBUILD
    (from rev 613485, python-netcdf4/trunk/PKGBUILD)

----------+
 PKGBUILD |   35 +++++++++++++++++++++++++++++++++++
 1 file changed, 35 insertions(+)

Copied: python-netcdf4/repos/community-staging-x86_64/PKGBUILD (from rev 613485, python-netcdf4/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-04-12 23:04:15 UTC (rev 613486)
@@ -0,0 +1,35 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Contributor: Spyros Stathopoulos <foucault.online at gmail.com>
+# Contributor: richli <rich at dranek dot com>
+# Contributor: rememberthemer <rememberthemer at _GMAIL_DOT_COM_>
+
+_pkg=netCDF4
+pkgname=python-${_pkg,,}
+pkgver=1.5.3
+pkgrel=3
+pkgdesc="Python/NumPy interface to the netCDF C library"
+arch=(x86_64)
+url="https://unidata.github.io/netcdf4-python"
+license=(MIT)
+depends=(python-numpy python-cftime netcdf)
+makedepends=(cython python-setuptools)
+source=(https://files.pythonhosted.org/packages/source/${_pkg::1}/${_pkg}/${_pkg}-${pkgver}.tar.gz)
+sha256sums=('2a3ca855848f4bbf07fac366da77a681fcead18c0a8813d91d46302f562dc3be')
+
+build() {
+    cd ${_pkg}-${pkgver}
+    USE_NCCONFIG=1 python setup.py build
+}
+
+check() {
+    cd ${_pkg}-${pkgver}/test
+    PYTHONPATH="../build/lib.linux-${CARCH}-3.8" python -B ./run_all.py
+}
+
+package() {
+    cd ${_pkg}-${pkgver}
+    USE_NCCONFIG=1 python setup.py install --prefix=/usr --root="${pkgdir}" --skip-build --optimize=2
+
+    install -Dm644 docs/netCDF4/* -t "${pkgdir}"/usr/share/doc/${pkgname}/docs/netCDF4
+    install -Dm644 COPYING -t "${pkgdir}"/usr/share/licenses/${pkgname}
+}


More information about the arch-commits mailing list