[arch-commits] Commit in python-netcdf4-openmpi/repos (2 files)

Bruno Pagani archange at archlinux.org
Mon Apr 13 14:37:33 UTC 2020


    Date: Monday, April 13, 2020 @ 14:37:32
  Author: archange
Revision: 613668

archrelease: copy trunk to community-staging-x86_64

Added:
  python-netcdf4-openmpi/repos/community-staging-x86_64/
  python-netcdf4-openmpi/repos/community-staging-x86_64/PKGBUILD
    (from rev 613667, python-netcdf4-openmpi/trunk/PKGBUILD)

----------+
 PKGBUILD |   35 +++++++++++++++++++++++++++++++++++
 1 file changed, 35 insertions(+)

Copied: python-netcdf4-openmpi/repos/community-staging-x86_64/PKGBUILD (from rev 613667, python-netcdf4-openmpi/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-04-13 14:37:32 UTC (rev 613668)
@@ -0,0 +1,35 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+_pkg=netCDF4
+_mpi=openmpi
+pkgname=python-${_pkg,,}-${_mpi}
+pkgver=1.5.3
+pkgrel=4
+pkgdesc="Python/NumPy interface to the netCDF C library (${_mpi} version)"
+arch=(x86_64)
+url="https://unidata.github.io/${_pkg,,}-python"
+license=(MIT)
+depends=(python-numpy python-cftime python-mpi4py "netcdf-${_mpi}")
+makedepends=(cython python-setuptools)
+conflicts=(python-netcdf4)
+provides=(python-netcdf4)
+source=(https://files.pythonhosted.org/packages/source/${_pkg::1}/${_pkg}/${_pkg}-${pkgver}.tar.gz)
+sha256sums=('2a3ca855848f4bbf07fac366da77a681fcead18c0a8813d91d46302f562dc3be')
+
+build() {
+    cd ${_pkg}-${pkgver}
+    USE_NCCONFIG=1 python setup.py build
+}
+
+check() {
+    cd ${_pkg}-${pkgver}/test
+    PYTHONPATH="../build/lib.linux-${CARCH}-3.8" python -B ./run_all.py
+}
+
+package() {
+    cd ${_pkg}-${pkgver}
+    USE_NCCONFIG=1 python setup.py install --prefix=/usr --root="${pkgdir}" --skip-build --optimize=2
+
+    install -Dm644 docs/netCDF4/* -t "${pkgdir}"/usr/share/doc/${pkgname}/docs/netCDF4
+    install -Dm644 COPYING -t "${pkgdir}"/usr/share/licenses/${pkgname}
+}


More information about the arch-commits mailing list