[arch-commits] Commit in haskell-doctemplates/repos (2 files)

[Felix Yan]

    Date: Tuesday, April 14, 2020 @ 21:59:20
  Author: felixonmars
Revision: 614302

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-doctemplates/repos/community-staging-x86_64/
  haskell-doctemplates/repos/community-staging-x86_64/PKGBUILD
    (from rev 614301, haskell-doctemplates/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: haskell-doctemplates/repos/community-staging-x86_64/PKGBUILD (from rev 614301, haskell-doctemplates/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-04-14 21:59:20 UTC (rev 614302)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=doctemplates
+pkgname=haskell-doctemplates
+pkgver=0.8.1
+pkgrel=17
+pkgdesc="Pandoc-style document templates"
+url="https://github.com/jgm/doctemplates"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-doclayout' 'haskell-hsyaml' 'haskell-safe'
+         'haskell-scientific' 'haskell-text-conversions' 'haskell-unordered-containers'
+         'haskell-vector')
+makedepends=('ghc' 'haskell-glob' 'haskell-tasty' 'haskell-tasty-golden' 'haskell-tasty-hunit'
+             'haskell-temporary')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('eb733421ff884e19a5c0c637fe1eaa3d0fcee9b6382939b148a0f9b493dc7b5c27344411bb542b7244a96fe613d8a587074936ff81ec367027364c98d338d6f6')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir="$pkgname" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}