[arch-commits] Commit in intel-compute-runtime/repos (2 files)

Bruno Pagani archange at archlinux.org
Thu Apr 16 01:12:19 UTC 2020


    Date: Thursday, April 16, 2020 @ 01:12:16
  Author: archange
Revision: 615090

archrelease: copy trunk to community-staging-x86_64

Added:
  intel-compute-runtime/repos/community-staging-x86_64/
  intel-compute-runtime/repos/community-staging-x86_64/PKGBUILD
    (from rev 615089, intel-compute-runtime/trunk/PKGBUILD)

----------+
 PKGBUILD |   41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

Copied: intel-compute-runtime/repos/community-staging-x86_64/PKGBUILD (from rev 615089, intel-compute-runtime/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-04-16 01:12:16 UTC (rev 615090)
@@ -0,0 +1,41 @@
+# Maintainer: Daniel Bermond <dbermond at archlinux.org>
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+pkgname=intel-compute-runtime
+pkgver=20.14.16441
+pkgrel=1
+pkgdesc="Intel(R) Graphics Compute Runtime for oneAPI Level Zero and OpenCL(TM) Driver"
+arch=(x86_64)
+url="https://01.org/compute-runtime"
+license=(MIT)
+depends=(gcc-libs intel-gmmlib intel-graphics-compiler)
+makedepends=(cmake libva level-zero-headers)
+optdepends=('libva: for cl_intel_va_api_media_sharing'
+            'libdrm: for cl_intel_va_api_media_sharing')
+provides=(opencl-driver level-zero-driver)
+source=(https://github.com/intel/compute-runtime/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha256sums=('169e7833121beea8ec69ff9249ca06f3bae981e14593c7a62f363d4991acb7e2')
+
+build() {
+    export CFLAGS+=" ${CPPFLAGS}"
+    export CXXFLAGS+=" ${CPPFLAGS}"
+    cmake -B build -S compute-runtime-${pkgver} \
+        -DCMAKE_BUILD_TYPE=Release \
+        -DCMAKE_INSTALL_PREFIX=/usr \
+        -DCMAKE_INSTALL_LIBDIR=lib \
+        -Wno-dev
+    make -C build
+}
+
+package() {
+    make -C build DESTDIR="${pkgdir}" install
+    install -Dm755 build/bin/libocloc.so -t "${pkgdir}"/usr/lib/intel-opencl
+    install -Dm644 compute-runtime-${pkgver}/LICENSE -t "${pkgdir}"/usr/share/licenses/${pkgname}
+    
+    local _lz_sover
+    local _lz_major
+    _lz_sover=$(find "${pkgdir}"/usr/lib -type f -name 'libze_intel_gpu.so.*.*.*' | sed 's/^.*\.so\.//')
+    _lz_major=${_lz_sover%%.*}
+    ln -s libze_intel_gpu.so.${_lz_sover} "${pkgdir}"/usr/lib/libze_intel_gpu.so
+    ln -s libze_intel_gpu.so.${_lz_sover} "${pkgdir}"/usr/lib/libze_intel_gpu.so.${_lz_major}
+}


More information about the arch-commits mailing list