[arch-commits] Commit in haskell-turtle/repos (2 files)

[Felix Yan]

    Date: Friday, April 17, 2020 @ 17:45:37
  Author: felixonmars
Revision: 615632

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-turtle/repos/community-staging-x86_64/
  haskell-turtle/repos/community-staging-x86_64/PKGBUILD
    (from rev 615631, haskell-turtle/trunk/PKGBUILD)

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Copied: haskell-turtle/repos/community-staging-x86_64/PKGBUILD (from rev 615631, haskell-turtle/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-04-17 17:45:37 UTC (rev 615632)
@@ -0,0 +1,51 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Thomas Dziedzic <gostrc at gmail.com>
+
+_hkgname=turtle
+pkgname=haskell-turtle
+pkgver=1.5.18
+pkgrel=3
+pkgdesc="Shell programming, Haskell-style"
+url="https://github.com/Gabriel439/Haskell-Turtle-Library"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-ansi-wl-pprint' 'haskell-async' 'haskell-clock' 'haskell-exceptions'
+         'haskell-foldl' 'haskell-hostname' 'haskell-managed' 'haskell-optparse-applicative'
+         'haskell-optional-args' 'haskell-streaming-commons' 'haskell-system-fileio'
+         'haskell-system-filepath' 'haskell-temporary' 'haskell-unix-compat')
+makedepends=('ghc' 'haskell-doctest')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('ec62e4be872ca6e32c72ff8bdfda534860e1f67d143885a3d25a5feda529fafed43aa4a84f660a2efd99242dff9df3281d95621bbd6fedec99e68d6b165b27d0')
+
+prepare() {
+    sed -i 's/]/, "-dynamic"]/' $_hkgname-$pkgver/test/Main.hs
+    sed -i -e '/semigroups/d' -e '/fail,/d' $_hkgname-$pkgver/$_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}