[arch-commits] Commit in haskell-wreq/repos (2 files)

[Felix Yan]

    Date: Friday, April 17, 2020 @ 18:45:57
  Author: felixonmars
Revision: 615674

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-wreq/repos/community-staging-x86_64/
  haskell-wreq/repos/community-staging-x86_64/PKGBUILD
    (from rev 615673, haskell-wreq/trunk/PKGBUILD)

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Copied: haskell-wreq/repos/community-staging-x86_64/PKGBUILD (from rev 615673, haskell-wreq/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-04-17 18:45:57 UTC (rev 615674)
@@ -0,0 +1,51 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=wreq
+pkgname=haskell-wreq
+pkgver=0.5.3.2
+pkgrel=185
+pkgdesc="An easy-to-use HTTP client library."
+url="https://github.com/bos/wreq"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-attoparsec' 'haskell-authenticate-oauth'
+         'haskell-base16-bytestring' 'haskell-case-insensitive' 'haskell-cryptonite'
+         'haskell-exceptions' 'haskell-hashable' 'haskell-http-client' 'haskell-http-client-tls'
+         'haskell-http-types' 'haskell-lens' 'haskell-lens-aeson' 'haskell-memory'
+         'haskell-mime-types' 'haskell-psqueues' 'haskell-time-locale-compat'
+         'haskell-unordered-containers' 'haskell-aeson-pretty' 'haskell-base64-bytestring'
+         'haskell-snap-core' 'haskell-snap-server' 'haskell-unix-compat' 'haskell-uuid')
+makedepends=('ghc' 'haskell-cabal-doctest' 'haskell-doctest' 'haskell-hunit' 'haskell-quickcheck'
+             'haskell-network-info' 'haskell-temporary' 'haskell-test-framework'
+             'haskell-test-framework-hunit' 'haskell-test-framework-quickcheck2' 'haskell-vector')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('5a2c62b973758cb8ce2bf20504e328090896fa25e7ee1f77b472d7cf5156e08b6d85bf4341ff45e44db1724070fcf3c0f21037fa0a79211a1767024328f7c779')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -fdoctest -f-aws -fhttpbin -f-developer
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test || warning "Tests failed"
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE.md "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.md
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE.md
+}