[arch-commits] Commit in python-scandir (3 files)

[Antonio Rojas]

    Date: Sunday, April 19, 2020 @ 17:21:59
  Author: arojas
Revision: 616531

archrelease: copy trunk to community-x86_64

Added:
  python-scandir/repos/
  python-scandir/repos/community-x86_64/
  python-scandir/repos/community-x86_64/PKGBUILD
    (from rev 616530, python-scandir/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: python-scandir/repos/community-x86_64/PKGBUILD (from rev 616530, python-scandir/trunk/PKGBUILD)
===================================================================
--- repos/community-x86_64/PKGBUILD	                        (rev 0)
+++ repos/community-x86_64/PKGBUILD	2020-04-19 17:21:59 UTC (rev 616531)
@@ -0,0 +1,44 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-scandir
+pkgname=(python-scandir python2-scandir)
+pkgver=1.10.0
+pkgrel=2
+pkgdesc="A better directory iterator and faster os.walk()"
+arch=('x86_64')
+url="https://github.com/benhoyt/scandir"
+license=('BSD')
+makedepends=('python2-setuptools' 'python-setuptools')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/benhoyt/scandir/archive/v$pkgver.tar.gz")
+sha512sums=('1641ee5060331fe35a5f97c26a14423cf94fe462cdf875746e29ce095d00b9fc34291efd50ee67f1613d19312a8ed737f29a5092a38afdb1dc817fadc52a508f')
+
+prepare() {
+  cp -r scandir-$pkgver{,-py2}
+}
+
+build() {
+  cd scandir-$pkgver
+  python setup.py build
+
+  cd ../scandir-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd scandir-$pkgver
+  LC_CTYPE=en_US.UTF-8 python test/run_tests.py
+}
+
+package_python-scandir() {
+  depends=('python')
+  cd scandir-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -D -m644 LICENSE.txt "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.txt
+}
+
+package_python2-scandir() {
+  depends=('python2')
+  cd scandir-$pkgver  
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -D -m644 LICENSE.txt "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.txt
+}