[arch-commits] Commit in nodejs/repos (3 files)

[Felix Yan]

    Date: Wednesday, April 22, 2020 @ 01:22:04
  Author: felixonmars
Revision: 617445

archrelease: copy trunk to community-testing-x86_64

Added:
  nodejs/repos/community-testing-x86_64/
  nodejs/repos/community-testing-x86_64/PKGBUILD
    (from rev 617443, nodejs/trunk/PKGBUILD)
  nodejs/repos/community-testing-x86_64/rebuild.list
    (from rev 617443, nodejs/trunk/rebuild.list)

--------------+
 PKGBUILD     |   57 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 rebuild.list |    2 ++
 2 files changed, 59 insertions(+)

Copied: nodejs/repos/community-testing-x86_64/PKGBUILD (from rev 617443, nodejs/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2020-04-22 01:22:04 UTC (rev 617445)
@@ -0,0 +1,57 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor  Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
+# Contributor: Thomas Dziedzic < gostrc at gmail >
+# Contributor: James Campos <james.r.campos at gmail.com>
+# Contributor: BlackEagle < ike DOT devolder AT gmail DOT com >
+# Contributor: Dongsheng Cai <dongsheng at moodle dot com>
+# Contributor: Masutu Subric <masutu.arch at googlemail dot com>
+# Contributor: TIanyi Cui <tianyicui at gmail.com>
+
+pkgname=nodejs
+pkgver=14.0.0
+pkgrel=1
+pkgdesc='Evented I/O for V8 javascript'
+arch=('x86_64')
+url='https://nodejs.org/'
+license=('MIT')
+depends=('openssl' 'zlib' 'icu' 'libuv' 'c-ares' 'libnghttp2') # 'http-parser' 'v8')
+makedepends=('python' 'procps-ng')
+optdepends=('npm: nodejs package manager')
+source=("nodejs-$pkgver.tar.gz::https://github.com/nodejs/node/archive/v$pkgver.tar.gz")
+sha512sums=('2bb051576b5ed9c919348cb2f6e5a54a3b12d5ff6e6f1d01a153eed58069c6bf740b62fb99087a830197624e3db865ba8ac767b7ed58962503a9f1100b4ebd50')
+
+build() {
+  cd node-$pkgver
+
+  ./configure \
+    --prefix=/usr \
+    --with-intl=system-icu \
+    --without-npm \
+    --shared-openssl \
+    --shared-zlib \
+    --shared-libuv \
+    --experimental-http-parser \
+    --shared-cares \
+    --shared-nghttp2
+    # --shared-v8
+    # --shared-http-parser
+
+  make
+}
+
+check() {
+  cd node-$pkgver
+  # Expected failure: https://github.com/nodejs/node/issues/11627
+  make test || warning "Tests failed"
+}
+
+package() {
+  cd node-$pkgver
+
+  make DESTDIR="$pkgdir" install
+
+  install -D -m644 LICENSE \
+    "$pkgdir"/usr/share/licenses/nodejs/LICENSE
+}
+
+# vim:set ts=2 sw=2 et:

Copied: nodejs/repos/community-testing-x86_64/rebuild.list (from rev 617443, nodejs/trunk/rebuild.list)
===================================================================
--- community-testing-x86_64/rebuild.list	                        (rev 0)
+++ community-testing-x86_64/rebuild.list	2020-04-22 01:22:04 UTC (rev 617445)
@@ -0,0 +1,2 @@
+apm
+bash-language-server