[arch-commits] Commit in nginx-mod-headers-more/repos (2 files)

Giancarlo Razzolini grazzolini at archlinux.org
Wed Apr 22 19:14:03 UTC 2020


    Date: Wednesday, April 22, 2020 @ 19:14:02
  Author: grazzolini
Revision: 617695

archrelease: copy trunk to community-staging-x86_64

Added:
  nginx-mod-headers-more/repos/community-staging-x86_64/
  nginx-mod-headers-more/repos/community-staging-x86_64/PKGBUILD
    (from rev 617694, nginx-mod-headers-more/trunk/PKGBUILD)

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Copied: nginx-mod-headers-more/repos/community-staging-x86_64/PKGBUILD (from rev 617694, nginx-mod-headers-more/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-04-22 19:14:02 UTC (rev 617695)
@@ -0,0 +1,39 @@
+# Maintainer: Massimiliano Torromeo <massimiliano.torromeo at gmail.com>
+
+pkgname=nginx-mod-headers-more
+pkgver=0.33
+pkgrel=7
+
+_modname="${pkgname#nginx-mod-}"
+_nginxver=1.18.0
+
+pkgdesc="Nginx module to set and clear input and output headers"
+arch=('x86_64')
+depends=("nginx=$_nginxver")
+url="https://github.com/openresty/headers-more-nginx-module"
+license=('BSD')
+
+source=(
+	https://nginx.org/download/nginx-$_nginxver.tar.gz{,.asc}
+	https://github.com/openresty/$_modname-nginx-module/archive/v$pkgver/$_modname-$pkgver.tar.gz
+)
+validpgpkeys=(B0F4253373F8F6F510D42178520A9993A1C052F8) # Maxim Dounin <mdounin at mdounin.ru>
+sha256sums=('4c373e7ab5bf91d34a4f11a0c9496561061ba5eee6020db272a17a7228d35f99'
+            'SKIP'
+            'a3dcbab117a9c103bc1ea5200fc00a7b7d2af97ff7fd525f16f8ac2632e30fbf')
+
+build() {
+	cd "$srcdir"/nginx-$_nginxver
+	./configure --with-compat --add-dynamic-module=../$_modname-nginx-module-$pkgver
+	make modules
+}
+
+package() {
+	cd "$srcdir"/nginx-$_nginxver/objs
+	for mod in *.so; do
+		install -Dm755 $mod "$pkgdir"/usr/lib/nginx/modules/$mod
+	done
+
+	install -Dm644 "$srcdir"/$_modname-nginx-module-$pkgver/README.markdown \
+	               "$pkgdir"/usr/share/licenses/$pkgname/README.markdown
+}


More information about the arch-commits mailing list