[arch-commits] Commit in helm/repos/community-x86_64 (PKGBUILD PKGBUILD)

Morten Linderud foxboron at archlinux.org
Wed Apr 22 22:13:18 UTC 2020


    Date: Wednesday, April 22, 2020 @ 22:13:17
  Author: foxboron
Revision: 617741

archrelease: copy trunk to community-x86_64

Added:
  helm/repos/community-x86_64/PKGBUILD
    (from rev 617740, helm/trunk/PKGBUILD)
Deleted:
  helm/repos/community-x86_64/PKGBUILD

----------+
 PKGBUILD |   89 +++++++++++++++++++++++++++----------------------------------
 1 file changed, 40 insertions(+), 49 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2020-04-22 22:13:07 UTC (rev 617740)
+++ PKGBUILD	2020-04-22 22:13:17 UTC (rev 617741)
@@ -1,49 +0,0 @@
-# Maintainer: Morten Linderud <foxboron at archlinux.org>
-# Contributor: Lukas Grossar <lukas.grossar at gmail.com>
-# Contributor: Ivan Shapovalov <intelfx at intelfx.name>
-# Contributor: Wayne Cheng <waynethecheng at gmail.com>
-# Contributor: Matthias Lisin <ml at visu.li>
-
-pkgname=helm
-pkgver=3.1.2
-pkgrel=3
-pkgdesc="The Kubernetes Package Manager"
-arch=("x86_64")
-url="https://helm.sh/"
-license=("Apache")
-depends=('glibc')
-makedepends=("go" "git")
-source=("git+https://github.com/helm/helm.git#tag=v$pkgver?signed")
-validpgpkeys=('672C657BE06B4B30969C4A57461449C25E36B98E')
-sha256sums=('SKIP')
-
-prepare() {
-    cd "${pkgname}"
-
-    # fix: update unit test for go 1.14 error string change (#7835)
-    # https://github.com/helm/helm/pull/7835
-    git cherry-pick -n 3706aa7ca666fda6d8301c55118fa1c092f124a2 
-
-    # Repair failing unit tests - failure caused by os.Stat return values for directory size on Linux.
-    # https://github.com/helm/helm/pull/7189
-    git cherry-pick -n e3976ab7a286ecbe1038a725fbc4149b95267abf
-}
-
-build() {
-    cd "${pkgname}"
-    export CGO_LDFLAGS="$LDFLAGS"
-    make GOFLAGS="-buildmode=pie -trimpath"
-}
-
-check(){
-    cd "${pkgname}"
-    export CGO_LDFLAGS="$LDFLAGS"
-    make GOFLAGS="-buildmode=pie -trimpath" test-unit
-}
-
-package(){
-    cd "${pkgname}"
-    install -Dm755 bin/helm -t "$pkgdir/usr/bin"
-    bin/helm completion bash | install -Dm644 /dev/stdin "$pkgdir/usr/share/bash-completion/completions/helm"
-    bin/helm completion zsh | install -Dm644 /dev/stdin "$pkgdir/usr/share/zsh/site-functions/_helm"
-}

Copied: helm/repos/community-x86_64/PKGBUILD (from rev 617740, helm/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2020-04-22 22:13:17 UTC (rev 617741)
@@ -0,0 +1,40 @@
+# Maintainer: Morten Linderud <foxboron at archlinux.org>
+# Contributor: Lukas Grossar <lukas.grossar at gmail.com>
+# Contributor: Ivan Shapovalov <intelfx at intelfx.name>
+# Contributor: Wayne Cheng <waynethecheng at gmail.com>
+# Contributor: Matthias Lisin <ml at visu.li>
+
+pkgname=helm
+pkgver=3.2.0
+pkgrel=1
+pkgdesc="The Kubernetes Package Manager"
+arch=("x86_64")
+url="https://helm.sh/"
+license=("Apache")
+depends=('glibc')
+makedepends=("go" "git")
+_commit=e11b7ce3b12db2941e90399e874513fbd24bcb71
+source=("git+https://github.com/helm/helm.git#commit=$_commit?signed")
+validpgpkeys=('672C657BE06B4B30969C4A57461449C25E36B98E')
+sha256sums=('SKIP')
+
+build() {
+    cd "${pkgname}"
+    export CGO_LDFLAGS="$LDFLAGS"
+    export CGO_CFLAGS="$CFLAGS"
+    make GOFLAGS="-buildmode=pie -trimpath"
+}
+
+check(){
+    cd "${pkgname}"
+    export CGO_LDFLAGS="$LDFLAGS"
+    export CGO_CFLAGS="$CFLAGS"
+    make GOFLAGS="-buildmode=pie -trimpath" test-unit
+}
+
+package(){
+    cd "${pkgname}"
+    install -Dm755 bin/helm -t "$pkgdir/usr/bin"
+    bin/helm completion bash | install -Dm644 /dev/stdin "$pkgdir/usr/share/bash-completion/completions/helm"
+    bin/helm completion zsh | install -Dm644 /dev/stdin "$pkgdir/usr/share/zsh/site-functions/_helm"
+}


More information about the arch-commits mailing list