[arch-commits] Commit in haskell-cryptohash-sha256/repos (2 files)

[Felix Yan]

    Date: Thursday, April 23, 2020 @ 10:41:37
  Author: felixonmars
Revision: 617965

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-cryptohash-sha256/repos/community-staging-x86_64/
  haskell-cryptohash-sha256/repos/community-staging-x86_64/PKGBUILD
    (from rev 617964, haskell-cryptohash-sha256/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: haskell-cryptohash-sha256/repos/community-staging-x86_64/PKGBUILD (from rev 617964, haskell-cryptohash-sha256/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-04-23 10:41:37 UTC (rev 617965)
@@ -0,0 +1,46 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=cryptohash-sha256
+pkgname=haskell-cryptohash-sha256
+pkgver=0.11.101.0
+pkgrel=14
+pkgdesc="Fast, pure and practical SHA-256 implementation"
+url="https://github.com/hvr/cryptohash-sha256"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-base16-bytestring')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('c755f1354fb5f1d6cfb54f73e39692392517954118d98b39ac4be7460e75a9ddc91ad641fed0f17e5fa33b62b7b0734af66526ea757e00716832572bb383c612')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i 's/<.*4.11/<5/' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -fexe
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+
+    mv "$pkgdir"/usr/bin/{,hs-}sha256sum
+}