[arch-commits] Commit in k3b/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Antonio Rojas]

    Date: Thursday, April 23, 2020 @ 14:07:17
  Author: arojas
Revision: 381205

archrelease: copy trunk to testing-x86_64

Added:
  k3b/repos/testing-x86_64/
  k3b/repos/testing-x86_64/PKGBUILD
    (from rev 381204, k3b/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: k3b/repos/testing-x86_64/PKGBUILD (from rev 381204, k3b/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2020-04-23 14:07:17 UTC (rev 381205)
@@ -0,0 +1,43 @@
+# Maintainer: Eric Bélanger <eric at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+
+pkgname=k3b
+pkgver=20.04.0
+pkgrel=1
+epoch=1
+pkgdesc="Feature-rich and easy to handle CD burning application"
+arch=(x86_64)
+url="https://userbase.kde.org/K3b"
+license=(GPL)
+depends=(libkcddb kcmutils knotifyconfig libmad kfilemetadata knewstuff
+         libmpcdec libdvdread libburn qt5-webkit)
+makedepends=(extra-cmake-modules kdoctools)
+optdepends=('cdrtools: for CD burning with cdrecord'
+            'dvd+rw-tools: for DVD burning support'
+            'vcdimager: for VCD burning support'
+            'emovix: for bootable multimedia CD/DVD support'
+            'cdrdao: for disk-at-once (DAO) mode support'
+            'cdparanoia: for CD ripping support' 'transcode: for DVD ripping support')
+groups=(kde-applications kdemultimedia)
+source=("https://download.kde.org/stable/release-service/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
+sha256sums=('1386002d37ff4745ad254ad503fd3326f053bf55667a07c6405234302f1c4e3f'
+            'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid at kde.org>
+              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck at kde.org>
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../$pkgname-$pkgver \
+    -DCMAKE_INSTALL_LIBEXECDIR=lib \
+    -DBUILD_TESTING=OFF
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+}