[arch-commits] Commit in haskell-regex-pcre/repos (2 files)

[Felix Yan]

    Date: Thursday, April 23, 2020 @ 14:45:24
  Author: felixonmars
Revision: 618223

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-regex-pcre/repos/community-staging-x86_64/
  haskell-regex-pcre/repos/community-staging-x86_64/PKGBUILD
    (from rev 618222, haskell-regex-pcre/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: haskell-regex-pcre/repos/community-staging-x86_64/PKGBUILD (from rev 618222, haskell-regex-pcre/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-04-23 14:45:24 UTC (rev 618223)
@@ -0,0 +1,43 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=regex-pcre
+pkgname=haskell-regex-pcre
+pkgver=0.95.0.0
+pkgrel=4
+pkgdesc="PCRE Backend for Text.Regex (regex-base)"
+url="https://hackage.haskell.org/package/regex-pcre"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' "haskell-regex-base" "pcre")
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('7c9ed0edd0c44d7118313c298c2658858117dd89eb7956566f5bb2fb75f2aaed70d201fda4102c46206b9951013bafee654ff39ed3c4bf9c5086f6c0cc217bdb')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i 's/< *4.14/<5/' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}