[arch-commits] Commit in paraview/repos (2 files)

[Bruno Pagani]

    Date: Friday, April 24, 2020 @ 17:07:21
  Author: archange
Revision: 619329

archrelease: copy trunk to community-staging-x86_64

Added:
  paraview/repos/community-staging-x86_64/
  paraview/repos/community-staging-x86_64/PKGBUILD
    (from rev 619328, paraview/trunk/PKGBUILD)

----------+
 PKGBUILD |   72 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 72 insertions(+)

Copied: paraview/repos/community-staging-x86_64/PKGBUILD (from rev 619328, paraview/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-04-24 17:07:21 UTC (rev 619329)
@@ -0,0 +1,72 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Maintainer: Mathieu Westphal <mathieu.westphal at kitware.com>
+# Contributor: Stéphane Gaudreault <stephane at archlinux.org>
+# Contributor: <xantares09 at hotmail.com>
+
+_pkg=paraview
+_mpi=openmpi
+pkgname=${_pkg}
+#-${_mpi}
+pkgver=5.8.0
+pkgrel=4
+pkgdesc="Parallel Visualization application using VTK (${_mpi} version)"
+arch=(x86_64)
+url="https://www.paraview.org"
+license=(BSD custom)
+depends=(boost-libs qt5-tools qt5-x11extras qt5-svg intel-tbb openmpi ffmpeg
+         ospray python-numpy cgns protobuf
+         double-conversion expat freetype2 gdal glew hdf5 libjpeg jsoncpp
+         libjsoncpp.so libxml2 lz4 xz python-mpi4py netcdf libogg libpng pdal
+         pugixml libtheora libtiff zlib)
+#        gl2ps
+#        libharu
+optdepends=(python-matplotlib)
+makedepends=(cmake boost mesa gcc-fortran ninja qt5-tools qt5-xmlpatterns eigen pegtl utf8cpp)
+conflicts=(vtk)
+source=("${url}/files/v${pkgver:0:3}/ParaView-v${pkgver/R/-R}.tar.xz"
+        paraview-cgns-4.1.patch::https://gitlab.kitware.com/paraview/paraview/-/commit/3d48a287141eb911b4888440e09c262743b4db3c.patch)
+sha256sums=('219e4107abf40317ce054408e9c3b22fb935d464238c1c00c0161f1c8697a3f9'
+            '3b6e68334849818a1f4eb35ef66a618240a2bb139555e22f13f0d561d5cc02eb')
+
+prepare() {
+    cd ParaView-v${pkgver/R/-R}
+    patch -p1 -i ../paraview-cgns-4.1.patch
+}
+
+build() {
+    # Note regarding use of system dependencies:
+    # GL2PS has non-upstreamed patches
+    # LIBHARU blocked by https://github.com/libharu/libharu/pull/157
+    cmake -B build -S ParaView-v${pkgver/R/-R} \
+        -DCMAKE_BUILD_TYPE=Release \
+        -DCMAKE_INSTALL_PREFIX=/usr \
+        -DPARAVIEW_ENABLE_FFMPEG=ON \
+        -DPARAVIEW_ENABLE_GDAL=ON \
+        -DPARAVIEW_ENABLE_MOTIONFX=ON \
+        -DPARAVIEW_ENABLE_PDAL=ON \
+        -DPARAVIEW_ENABLE_VISITBRIDGE=ON \
+        -DPARAVIEW_ENABLE_XDMF3=ON \
+        -DPARAVIEW_INSTALL_DEVELOPMENT_FILES=ON \
+        -DPARAVIEW_USE_MPI=ON \
+        -DPARAVIEW_USE_PYTHON=ON \
+        -DPARAVIEW_USE_RAYTRACING=ON \
+        -DPARAVIEW_BUILD_WITH_EXTERNAL=ON \
+        -DVTK_MODULE_USE_EXTERNAL_VTK_gl2ps=OFF \
+        -DVTK_MODULE_USE_EXTERNAL_VTK_libharu=OFF \
+        -DVTK_SMP_IMPLEMENTATION_TYPE=TBB \
+        -DVTKm_ENABLE_MPI=ON \
+        -DVTK_MODULE_ENABLE_VTK_IOGDAL=YES \
+        -DVTK_MODULE_ENABLE_VTK_IOPDAL=YES \
+        -DCMAKE_C_FLAGS="-DH5_USE_110_API" \
+        -DCMAKE_CXX_FLAGS="-DH5_USE_110_API" \
+        -GNinja
+
+    ninja -C build ${MAKEFLAGS}
+}
+
+package() {
+    DESTDIR="${pkgdir}" ninja -C build install
+
+    # Install license
+    install -Dm644 ParaView-v${pkgver/R/-R}/License_v1.2.txt "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
+}