[arch-commits] Commit in haskell-persistent-sqlite/repos (2 files)

Felix Yan felixonmars at archlinux.org
Sat Apr 25 13:17:22 UTC 2020


    Date: Saturday, April 25, 2020 @ 13:17:21
  Author: felixonmars
Revision: 620661

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-persistent-sqlite/repos/community-staging-x86_64/
  haskell-persistent-sqlite/repos/community-staging-x86_64/PKGBUILD
    (from rev 620660, haskell-persistent-sqlite/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: haskell-persistent-sqlite/repos/community-staging-x86_64/PKGBUILD (from rev 620660, haskell-persistent-sqlite/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-04-25 13:17:21 UTC (rev 620661)
@@ -0,0 +1,48 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=persistent-sqlite
+pkgname=haskell-persistent-sqlite
+pkgver=2.10.6.2
+pkgrel=51
+pkgdesc="Backend for the persistent library using sqlite3"
+url="https://www.yesodweb.com/book/persistent"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'sqlite' 'haskell-aeson' 'haskell-conduit' 'haskell-microlens-th'
+         'haskell-monad-logger' 'haskell-persistent' 'haskell-resource-pool' 'haskell-resourcet'
+         'haskell-unliftio-core' 'haskell-unordered-containers')
+makedepends=('ghc' 'haskell-fast-logger' 'haskell-hspec' 'haskell-hunit'
+             'haskell-persistent-template' 'haskell-persistent-test' 'haskell-quickcheck'
+             'haskell-system-fileio' 'haskell-system-filepath' 'haskell-temporary')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('b1db41bf77ae53b99c28f3224c9a2b7335faa4a78c96487270249959cc9491fa542e28d38dd63a2b417580f6a41608ffcee152e8609fe16392005c728862c7bc')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-build-sanity-exe -fsystemlib -fuse-pkgconfig
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}


More information about the arch-commits mailing list